ParticleTrackEventBuffer.f90

Go to the documentation of this file.

!> @brief Particle event buffering strategies.
module particletrackeventbuffermodule
 
  use kindmodule, only: dp, i4b, lgp
  use errorutilmodule, only: pstop
 
  implicit none
 
  !> @brief Flat record of a particle track event.
  type :: particletrackrecordtype
    integer(I4B) :: kper, kstp, imdl, iprp, irpt, ilay, icu, izone
    integer(I4B) :: istatus, ireason
    real(dp) :: trelease, ttrack, x, y, z
    character(len=40) :: name
  end type particletrackrecordtype
 
  !> @brief Output file containing all or some particle pathlines.
  !!
  !! Can be associated with a particle release point (PRP) package
  !! or with an entire model, and can be binary or text (CSV).
  !<
  type :: particletrackfiletype
    private
    integer(I4B), public :: iun = 0 !< file unit number
    logical(LGP), public :: csv = .false. !< whether the file is binary or CSV
    integer(I4B), public :: iprp = -1 !< -1 is model-level file, 0 is exchange PRP
  end type particletrackfiletype
 
  !> @brief Event buffering strategy
  type, abstract :: particletrackeventbuffertype
    integer(I4B) :: nrecords = 0 !< number of records stored
  contains
    procedure :: init => buffer_init !< open/allocate resources
    procedure(buffer_append), deferred :: append !< buffer one record
    procedure(buffer_flush), deferred :: flush !< write buffered records, reset
    procedure(buffer_simple), deferred :: discard !< reset without writing
    procedure(buffer_simple), deferred :: destroy !< release resources
  end type particletrackeventbuffertype
 
  abstract interface
    subroutine buffer_append(this, rec)
      import particletrackeventbuffertype, particletrackrecordtype
      class(particletrackeventbuffertype) :: this
      type(particletrackrecordtype), intent(in) :: rec
    end subroutine buffer_append
 
    subroutine buffer_flush(this, files)
      import particletrackeventbuffertype, particletrackfiletype
      class(particletrackeventbuffertype) :: this
      type(particletrackfiletype), intent(in) :: files(:)
    end subroutine buffer_flush
 
    ! Shared interface for discard and destroy: both take only `this`.
    subroutine buffer_simple(this)
      import particletrackeventbuffertype
      class(particletrackeventbuffertype) :: this
    end subroutine buffer_simple
  end interface
 
contains
 
  subroutine buffer_init(this)
    class(particletrackeventbuffertype) :: this
  end subroutine buffer_init
 
  !> @brief Save an event record to a binary or CSV file.
  subroutine save_record(iun, rec, csv)
    integer(I4B), intent(in) :: iun
    type(particletrackrecordtype), intent(in) :: rec
    logical(LGP), intent(in) :: csv
 
    if (csv) then
      write (iun, '(*(G0,:,","))') &
        rec%kper, rec%kstp, rec%imdl, rec%iprp, rec%irpt, &
        rec%ilay, rec%icu, rec%izone, rec%istatus, rec%ireason, &
        rec%trelease, rec%ttrack, rec%x, rec%y, rec%z, trim(rec%name)
    else
      write (iun) &
        rec%kper, rec%kstp, rec%imdl, rec%iprp, rec%irpt, &
        rec%ilay, rec%icu, rec%izone, rec%istatus, rec%ireason, &
        rec%trelease, rec%ttrack, rec%x, rec%y, rec%z, rec%name
    end if
  end subroutine save_record
 
end module particletrackeventbuffermodule