LangmuirIsotherm.f90

Go to the documentation of this file.

module langmuirisothermmodule
 
  use kindmodule, only: dp, i4b
  use isotherminterfacemodule, only: isothermtype
 
  implicit none
  private
  public :: langmuirisothermtype
 
  !> @brief Langmuir isotherm implementation of `IsothermType`.
  !!
  !! Sorbed concentration is cs = (Sbar*Kl*c)/(1 + Kl*c).
  !<
  type, extends(isothermtype) :: langmuirisothermtype
    real(dp), pointer, dimension(:) :: kl => null() !< Langmuir constant
    real(dp), pointer, dimension(:) :: sbar => null() !< Total concentration of sorption sites
  contains
    procedure :: value
    procedure :: derivative
  end type langmuirisothermtype
 
  interface langmuirisothermtype
    module procedure constructor
  end interface langmuirisothermtype
 
contains
  !> @brief Constructor for Langmuir isotherm
  !<
  function constructor(Kl, Sbar) Result(isotherm)
    ! -- return
    type(langmuirisothermtype) :: isotherm
    ! -- dummy
    real(dp), pointer, dimension(:), intent(in) :: kl !< Langmuir constant
    real(dp), pointer, dimension(:), intent(in) :: sbar !< Total concentration of sorption sites
    ! -- local
 
    isotherm%Kl => kl
    isotherm%Sbar => sbar
 
  end function constructor
 
  !> @brief Evaluate the isotherm at a given node
  !<
  function value(this, c, n) result(val)
    ! -- return
    real(dp) :: val !< isotherm value
    ! -- dummy
    class(langmuirisothermtype), intent(in) :: this
    real(dp), dimension(:), intent(in) :: c !< concentration array
    integer(I4B), intent(in) :: n !< node index
    ! -- local
    real(dp) :: denom
 
    if (c(n) > 0.0_dp) then
      denom = 1.0_dp + this%Kl(n) * c(n)
      val = (this%Sbar(n) * this%Kl(n) * c(n)) / denom
    else
      val = 0.0_dp
    end if
  end function value
 
  !> @brief Evaluate derivative of the isotherm at a given node
  !<
  function derivative(this, c, n) result(derv)
    ! -- return
    real(dp) :: derv !< derivative d(value)/dc evaluated at c
    ! -- dummy
    class(langmuirisothermtype), intent(in) :: this
    real(dp), dimension(:), intent(in) :: c !< concentration array
    integer(I4B), intent(in) :: n !< node index
    ! -- local
    real(dp) :: denom
 
    if (c(n) > 0.0_dp) then
      denom = (1.0_dp + this%Kl(n) * c(n))**2.0_dp
      derv = (this%Sbar(n) * this%Kl(n)) / denom
    else
      derv = 0.0_dp
    end if
  end function derivative
 
end module langmuirisothermmodule