LinearIsotherm.f90

Go to the documentation of this file.

module linearisothermsmodule
 
  use kindmodule, only: dp, i4b
  use isotherminterfacemodule, only: isothermtype
 
  implicit none
  private
  public :: linearisothermtype
 
  !> @brief Linear (Kd) isotherm implementation of `IsothermType`.
  !>
  !> Sorbed concentration is computed as cs = Kd*c.
  !<
  type, extends(isothermtype) :: linearisothermtype
    real(dp), pointer, dimension(:) :: kd => null() !< distribution coefficient
  contains
    procedure :: value
    procedure :: derivative
  end type linearisothermtype
 
  interface linearisothermtype
    module procedure constructor
  end interface linearisothermtype
 
contains
  !> @brief Constructor for Linear isotherm
  !<
  function constructor(Kd) Result(isotherm)
    ! -- return
    type(linearisothermtype) :: isotherm
    ! -- dummy
    real(dp), pointer, dimension(:), intent(in) :: kd !< distribution coefficient
    ! -- local
 
    isotherm%Kd => kd
 
  end function constructor
 
  !> @brief Evaluate the isotherm at a given node
  !<
  function value(this, c, n) result(val)
    ! -- return
    real(dp) :: val !< isotherm value
    ! -- dummy
    class(linearisothermtype), intent(in) :: this
    real(dp), dimension(:), intent(in) :: c !< concentration array
    integer(I4B), intent(in) :: n !< node index
 
    val = this%Kd(n) * c(n)
  end function value
 
  !> @brief Evaluate derivative of the isotherm at a given node
  !<
  function derivative(this, c, n) result(derv)
    ! -- return
    real(dp) :: derv !< derivative d(value)/dc evaluated at c
    ! -- dummy
    class(linearisothermtype), intent(in) :: this
    real(dp), dimension(:), intent(in) :: c !< concentration array
    integer(I4B), intent(in) :: n !< node index
    ! -- local
 
    derv = this%Kd(n)
  end function derivative
 
end module linearisothermsmodule