ParticleEvent.f90

Go to the documentation of this file.

module particleeventmodule
  use kindmodule, only: dp, i4b, lgp
  use constantsmodule, only: lenhugeline
  use errorutilmodule, only: pstop
  use particlemodule, only: particletype
  implicit none
 
  private
  public :: particleeventtype
  public :: release
  public :: featexit
  public :: timestep
  public :: terminate
  public :: weaksink
  public :: usertime
  public :: dropped
 
  !> @brief Particle event enumeration.
  !!
  !! A number of events may occur to particles, each of which may (or may
  !! not) be of interest to the user. The user selects events to report.
  !<
  enum, bind(C)
    enumerator :: release = 0 !< particle was released
    enumerator :: featexit = 1 !< particle exited a grid feature
    enumerator :: timestep = 2 !< time step ended
    enumerator :: terminate = 3 !< particle terminated
    enumerator :: weaksink = 4 !< particle entered a weak sink
    enumerator :: usertime = 5 !< user-specified tracking time
    enumerator :: dropped = 6 !< particle dropped to the water table
  end enum
 
  !> @brief Base type for particle events.
  !!
  !! Events may be identical except for their type/code, reflecting the
  !! fact that several events of interest may occur at a given moment.
  type, abstract :: particleeventtype
    integer(I4B) :: imdl, iprp, irpt ! release model, package, and point
    real(dp) :: trelease = 0.0_dp ! release time
    integer(I4B) :: kper = 0, kstp = 0 ! period and step
    integer(I4B) :: ilay, icu, izone = 0
    real(dp) :: ttrack = 0.0_dp ! simulation time
    real(dp) :: x = 0.0_dp, y = 0.0_dp, z = 0.0_dp ! particle position
    integer(I4B) :: istatus = -1 ! status code
  contains
    procedure(get_int), deferred :: get_code
    procedure(get_str), deferred :: get_verb
    procedure(get_str), deferred :: get_text
    procedure :: log
  end type particleeventtype
 
  abstract interface
    function get_int(this) result(int)
      IMPORT i4b
      IMPORT particleeventtype
      class(particleeventtype), intent(in) :: this
      integer(I4B) :: int
    end function get_int
 
    function get_str(this) result(str)
      IMPORT particleeventtype
      class(particleeventtype), intent(in) :: this
      character(len=:), allocatable :: str
    end function get_str
  end interface
 
contains
 
  subroutine log(this, iun)
    class(particleeventtype), intent(inout) :: this
    integer(I4B), intent(in) :: iun
    if (iun >= 0) write (iun, '(*(G0))') this%get_text()
  end subroutine log
 
end module particleeventmodule