simmodule Module Reference

This module contains simulation methods. More...

Functions/Subroutines
integer(i4b) function, public	count_errors ()
	Return number of errors. More...
integer(i4b) function, public	count_warnings ()
	Return number of warnings. More...
integer(i4b) function, public	count_notes ()
	Return the number of notes stored. More...
subroutine, public	maxerrors (imax)
	Set the maximum number of errors to be stored. More...
subroutine, public	store_error (msg, terminate)
	Store an error message. More...
subroutine	get_filename (iunit, fname)
	Get the file name. More...
subroutine, public	store_error_unit (iunit, terminate)
	Store the file unit number. More...
subroutine, public	store_error_filename (filename, terminate)
	Store the erroring file name. More...
subroutine, public	store_warning (msg, substring)
	Store warning message. More...
subroutine, public	deprecation_warning (cblock, cvar, cver, endmsg, iunit)
	Store deprecation warning message. More...
subroutine, public	store_note (note)
	Store note. More...
subroutine, public	ustop (stopmess, ioutlocal)
	Stop the simulation. More...
subroutine	print_final_message (stopmess, ioutlocal)
	Print the final messages. More...
subroutine, public	converge_reset ()
	Reset the simulation convergence flag. More...
subroutine, public	converge_check (hasConverged)
	Simulation convergence check. More...
subroutine, public	initial_message ()
	Print the header and initializes messaging. More...
subroutine, public	final_message ()
	Create final message. More...
subroutine	sim_closefiles ()
	Close all open files. More...

Variables
type(messagestype)	sim_errors
type(messagestype)	sim_uniterrors
type(messagestype)	sim_warnings
type(messagestype)	sim_notes

Detailed Description

This module contains simulation methods for storing warning and error messages and notes. This module also has methods for counting warnings, errors, and notes in addition to stopping the simulation. The module does not have any dependencies on models, exchanges, or solutions in a simulation.

Function/Subroutine Documentation

converge_check()

subroutine, public simmodule::converge_check

(

logical, intent(inout)

hasConverged

)

Subroutine to check simulation convergence. If the continue option is set the simulation convergence flag is set to True if the simulation did not actually converge for a time step and the non-convergence counter is incremented.

Parameters

[in,out]

hasconverged

boolean indicting if the simulation is considered converged

Definition at line 402 of file Sim.f90.

    ! -- modules
    use simvariablesmodule, only: isimcnvg, numnoconverge, isimcontinue
    ! -- dummy variables
    logical, intent(inout) :: hasConverged !< boolean indicting if the
                                           !! simulation is considered converged
    ! -- format
    character(len=*), parameter :: fmtfail = &
      "(1x, 'Simulation convergence failure.', &
      &' Simulation will terminate after output and deallocation.')"
    !
    ! -- Initialize hasConverged to True
    hasconverged = .true.
    !
    ! -- Count number of failures
    if (isimcnvg == 0) then
      numnoconverge = numnoconverge + 1
    end if
    !
    ! -- Continue if 'CONTINUE' specified in simulation control file
    if (isimcontinue == 1) then
      if (isimcnvg == 0) then
        isimcnvg = 1
      end if
    end if
    !
    ! -- save simulation failure message
    if (isimcnvg == 0) then
      call write_message('', fmt=fmtfail, iunit=iout)
      hasconverged = .false.
    end if
 

Here is the call graph for this function:

Here is the caller graph for this function:

converge_reset()

subroutine, public simmodule::converge_reset

Subroutine to reset the simulation convergence flag.

Definition at line 389 of file Sim.f90.

    use simvariablesmodule, only: isimcnvg
    isimcnvg = 1

Here is the caller graph for this function:

count_errors()

integer(i4b) function, public simmodule::count_errors

Function to return the number of errors messages that have been stored.

Returns

ncount number of error messages stored

Definition at line 58 of file Sim.f90.

    integer(I4B) :: ncount
    ncount = sim_errors%count()

count_notes()

integer(i4b) function, public simmodule::count_notes

Definition at line 77 of file Sim.f90.

    integer(I4B) :: ncount
    ncount = sim_notes%count()

count_warnings()

integer(i4b) function, public simmodule::count_warnings

Function to return the number of warning messages that have been stored.

Returns

ncount number of warning messages stored

Definition at line 70 of file Sim.f90.

    integer(I4B) :: ncount
    ncount = sim_warnings%count()

deprecation_warning()

subroutine, public simmodule::deprecation_warning	(	character(len=*), intent(in)	cblock,
		character(len=*), intent(in)	cvar,
		character(len=*), intent(in)	cver,
		character(len=*), intent(in), optional	endmsg,
		integer(i4b), intent(in), optional	iunit
	)

Subroutine to store a warning message for deprecated variables and printing at the end of simulation.

Parameters

[in]	cblock	block name
[in]	cvar	variable name
[in]	cver	version when variable was deprecated
[in]	endmsg	optional user defined message to append at the end of the deprecation warning
[in]	iunit	optional input file unit number with the deprecated variable

Definition at line 256 of file Sim.f90.

    ! -- modules
    use arrayhandlersmodule, only: expandarray
    ! -- dummy variables
    character(len=*), intent(in) :: cblock !< block name
    character(len=*), intent(in) :: cvar !< variable name
    character(len=*), intent(in) :: cver !< version when variable was deprecated
    character(len=*), intent(in), optional :: endmsg !< optional user defined message to append
                                                     !! at the end of the deprecation warning
    integer(I4B), intent(in), optional :: iunit !< optional input file unit number with
                                                !! the deprecated variable
    ! -- local variables
    character(len=MAXCHARLEN) :: message
    character(len=LINELENGTH) :: fname
    !
    ! -- build message
    write (message, '(a)') &
      trim(cblock)//" BLOCK VARIABLE '"//trim(cvar)//"'"
    if (present(iunit)) then
      call get_filename(iunit, fname)
      write (message, '(a,1x,3a)') &
        trim(message), "IN FILE '", trim(fname), "'"
    end if
    write (message, '(a)') &
      trim(message)//' WAS DEPRECATED IN VERSION '//trim(cver)//'.'
    if (present(endmsg)) then
      write (message, '(a,1x,2a)') trim(message), trim(endmsg), '.'
    end if
    !
    ! -- store warning
    call sim_warnings%store(message)
 

Here is the call graph for this function:

Here is the caller graph for this function:

final_message()

subroutine, public simmodule::final_message

Subroutine that creates the appropriate final message and terminates the program with an error message, if necessary.

Definition at line 472 of file Sim.f90.

    ! -- modules
    use simvariablesmodule, only: isimcnvg, numnoconverge, ireturnerr, &
                                  isimcontinue
    ! -- formats
    character(len=*), parameter :: fmtnocnvg = &
      &"(1x, 'Simulation convergence failure occurred ', i0, ' time(s).')"
    !
    ! -- Write message if nonconvergence occurred in at least one timestep
    if (numnoconverge > 0) then
      write (warnmsg, fmtnocnvg) numnoconverge
      if (isimcontinue == 0) then
        call sim_errors%store(warnmsg)
      else
        call sim_warnings%store(warnmsg)
      end if
    end if
    !
    ! -- write final message
    if (isimcnvg == 0) then
      call print_final_message('Premature termination of simulation.', iout)
    else
      call print_final_message('Normal termination of simulation.', iout)
    end if
    !
    ! -- If the simulation did not converge and the continue
    !    option was not set, then set the return code to 1.  The
    !    purpose of setting the returncode this way is that the
    !    program will terminate without a stop code if the simulation
    !    reached the end and the continue flag was set, even if the
    !    the simulation did not converge.
    if (isimcnvg == 0 .and. isimcontinue == 0) then
      ireturnerr = 1
    end if
    !
    ! -- destroy messages
    call sim_errors%deallocate()
    call sim_uniterrors%deallocate()
    call sim_warnings%deallocate()
    call sim_notes%deallocate()
    !
    ! -- return or halt
    if (iforcestop == 1) then
      call pstop(ireturnerr)
    end if
 

Here is the call graph for this function:

Here is the caller graph for this function:

get_filename()

subroutine simmodule::get_filename ( integer(i4b), intent(in)  iunit, character(len=*), intent(inout)  fname  )

private

Subroutine to get the file name from the unit number for a open file. If the INQUIRE function returns the full path (for example, the INTEL compiler) then the returned file name (fname) is limited to the filename without the path.

Parameters

[in]	iunit	open file unit number
[in,out]	fname	file name attached to the open file unit number

Definition at line 123 of file Sim.f90.

    ! -- dummy variables
    integer(I4B), intent(in) :: iunit !< open file unit number
    character(len=*), intent(inout) :: fname !< file name attached to the open file unit number
    ! -- local variables
    integer(I4B) :: ipos
    integer(I4B) :: ios
    integer(I4B) :: ilen
    !
    ! -- get file name from unit number
    ipos = 0
    inquire (unit=iunit, name=fname)
    !
    ! -- determine the operating system
    ios = get_os()
    !
    ! -- extract filename from full path, if present
    !    forward slash on linux, unix, and osx
    if (ios /= oswin) then
      ipos = index(fname, '/', back=.true.)
    end if
    !
    ! -- check for backslash on windows or undefined os and
    !    forward slashes were not found
    if (ios == oswin .or. ios == osundef) then
      if (ipos < 1) then
        ipos = index(fname, '\', back=.true.)
      end if
    end if
    !
    ! -- exclude the path from the file name
    if (ipos > 0) then
      ilen = len_trim(fname)
      write (fname, '(a)') fname(ipos + 1:ilen)//' '
    end if
 

Here is the call graph for this function:

Here is the caller graph for this function:

initial_message()

subroutine, public simmodule::initial_message

Subroutine that prints the initial message and initializes the notes, warning messages, unit errors, and error messages.

Definition at line 442 of file Sim.f90.

    ! -- modules
    use versionmodule, only: write_listfile_header
    use simvariablesmodule, only: simulation_mode, nr_procs
    !
    ! -- initialize message lists
    call sim_errors%init()
    call sim_uniterrors%init()
    call sim_warnings%init()
    call sim_notes%init()
    !
    ! -- Write banner to screen (unit stdout)
    call write_listfile_header(istdout, write_kind_info=.false., &
                               write_sys_command=.false.)
    !
    call write_message(' MODFLOW runs in '//trim(simulation_mode)//' mode', &
                       skipafter=1)
    !
    if (simulation_mode == 'PARALLEL' .and. nr_procs == 1) then
      call store_warning('Running parallel MODFLOW on only 1 process')
    end if
    !

Here is the call graph for this function:

Here is the caller graph for this function:

maxerrors()

subroutine, public simmodule::maxerrors

(

integer(i4b), intent(in)

imax

)

Parameters

[in]

imax

maximum number of error messages that will be stored

Definition at line 84 of file Sim.f90.

    integer(I4B), intent(in) :: imax !< maximum number of error messages that will be stored
    call sim_errors%set_max(imax)

Here is the caller graph for this function:

print_final_message()

subroutine simmodule::print_final_message ( character, dimension (*), intent(in), optional  stopmess, integer(i4b), intent(in), optional  ioutlocal  )

private

Subroutine to print the notes, warnings, errors and the final message (if passed). The subroutine also closes all open files.

Parameters

[in]	stopmess	optional message to print before stopping the simulation
[in]	ioutlocal	optional output file to final message to

Definition at line 333 of file Sim.f90.

    ! -- dummy variables
    character, optional, intent(in) :: stopmess * (*) !< optional message to print before
                                                      !! stopping the simulation
    integer(I4B), optional, intent(in) :: ioutlocal !< optional output file to
                                                    !! final message to
    ! -- local variables
    character(len=*), parameter :: fmt = '(1x,a)'
    character(len=*), parameter :: msg = 'Stopping due to error(s)'
    !
    ! -- print the accumulated messages
    if (isim_level >= vall) then
      call sim_notes%write_all('NOTES:', 'note(s)', &
                               iunit=iout)
      call sim_warnings%write_all('WARNING REPORT:', 'warning(s)', &
                                  iunit=iout)
    end if
    call sim_errors%write_all('ERROR REPORT:', 'error(s)', iunit=iout)
    call sim_uniterrors%write_all('UNIT ERROR REPORT:', &
                                  'file unit error(s)', iunit=iout)
    !
    ! -- write a stop message, if one is passed
    if (present(stopmess)) then
      if (stopmess .ne. ' ') then
        call write_message(stopmess, fmt=fmt, iunit=iout)
        call write_message(stopmess, fmt=fmt)
        if (present(ioutlocal)) then
          if (ioutlocal > 0 .and. ioutlocal /= iout) then
            write (ioutlocal, fmt) trim(stopmess)
            close (ioutlocal)
          end if
        end if
      end if
    end if
    !
    ! -- write console buffer output to stdout
    flush (istdout)
    !
    ! -- determine if an error condition has occurred
    if (sim_errors%count() > 0) then
      ireturnerr = 2
      if (present(ioutlocal)) then
        if (ioutlocal > 0 .and. ioutlocal /= iout) write (ioutlocal, fmt) msg
      end if
    end if
    !
    ! -- close all open files
    call sim_closefiles()
 

Here is the call graph for this function:

Here is the caller graph for this function:

sim_closefiles()

subroutine simmodule::sim_closefiles

Subroutine that closes all open files at the end of the simulation.

Definition at line 525 of file Sim.f90.

    ! -- local variables
    integer(I4B) :: i
    logical :: opened
    character(len=7) :: output_file
    !
    ! -- close all open file units
    do i = iustart, iunext - 1
      !
      ! -- determine if file unit i is open
      inquire (unit=i, opened=opened)
      !
      ! -- skip file units that are no longer open
      if (.not. opened) then
        cycle
      end if
      !
      ! -- flush the file if it can be written to
      inquire (unit=i, write=output_file)
      if (trim(adjustl(output_file)) == 'YES') then
        flush (i)
      end if
      !
      ! -- close file unit i
      close (i)
    end do
 

Here is the caller graph for this function:

store_error()

subroutine, public simmodule::store_error	(	character(len=*), intent(in)	msg,
		logical, intent(in), optional	terminate
	)

Parameters

[in]	msg	error message
[in]	terminate	boolean indicating if the simulation should be terminated

Definition at line 91 of file Sim.f90.

    ! -- dummy variable
    character(len=*), intent(in) :: msg !< error message
    logical, optional, intent(in) :: terminate !< boolean indicating if the simulation should be terminated
    ! -- local variables
    logical :: lterminate
    !
    ! -- process optional variables
    if (present(terminate)) then
      lterminate = terminate
    else
      lterminate = .false.
    end if
    !
    ! -- store error
    call sim_errors%store(msg)
    !
    ! -- terminate the simulation
    if (lterminate) then
      call ustop()
    end if
 

Here is the call graph for this function:

store_error_filename()

subroutine, public simmodule::store_error_filename	(	character(len=*), intent(in)	filename,
		logical, intent(in), optional	terminate
	)

Subroutine to store the file name issuing an error. By default, the simulation is terminated when this subroutine is called

Parameters

[in]	filename	erroring file name
[in]	terminate	boolean indicating if the simulation should be terminated

Definition at line 203 of file Sim.f90.

    ! -- dummy variables
    character(len=*), intent(in) :: filename !< erroring file name
    logical, optional, intent(in) :: terminate !< boolean indicating if the simulation should be terminated
    ! -- local variables
    logical :: lterminate
    character(len=LINELENGTH) :: errmsg
    !
    ! -- process optional variables
    if (present(terminate)) then
      lterminate = terminate
    else
      lterminate = .true.
    end if
    !
    ! -- store error unit
    write (errmsg, '(3a)') &
      "ERROR OCCURRED WHILE READING FILE '", trim(adjustl(filename)), "'"
    call sim_uniterrors%store(errmsg)
    !
    ! -- terminate the simulation
    if (lterminate) then
      call ustop()
    end if
 

Here is the call graph for this function:

store_error_unit()

subroutine, public simmodule::store_error_unit	(	integer(i4b), intent(in)	iunit,
		logical, intent(in), optional	terminate
	)

Subroutine to convert the unit number for a open file to a file name and indicate that there is an error reading from the file. By default, the simulation is terminated when this subroutine is called.

Parameters

[in]	iunit	open file unit number
[in]	terminate	boolean indicating if the simulation should be terminated

Definition at line 168 of file Sim.f90.

    ! -- dummy variables
    integer(I4B), intent(in) :: iunit !< open file unit number
    logical, optional, intent(in) :: terminate !< boolean indicating if the simulation should be terminated
    ! -- local variables
    logical :: lterminate
    character(len=LINELENGTH) :: fname
    character(len=LINELENGTH) :: errmsg
    !
    ! -- process optional variables
    if (present(terminate)) then
      lterminate = terminate
    else
      lterminate = .true.
    end if
    !
    ! -- store error unit
    call get_filename(iunit, fname)
    write (errmsg, '(3a)') &
      "Error occurred while reading file '", trim(adjustl(fname)), "'"
    call sim_uniterrors%store(errmsg)
    !
    ! -- terminate the simulation
    if (lterminate) then
      call ustop()
    end if
 

Here is the call graph for this function:

store_note()

subroutine, public simmodule::store_note

(

character(len=*), intent(in)

note

)

Subroutine to store a note for printing at the end of the simulation.

Definition at line 295 of file Sim.f90.

    ! -- modules
    use arrayhandlersmodule, only: expandarray
    ! -- dummy variables
    character(len=*), intent(in) :: note !< note
    !
    ! -- store note
    call sim_notes%store(note)
 

store_warning()

subroutine, public simmodule::store_warning	(	character(len=*), intent(in)	msg,
		character(len=*), intent(in), optional	substring
	)

Subroutine to store a warning message for printing at the end of the simulation.

Parameters

[in]	msg	warning message
[in]	substring	optional string that can be used to prevent storing duplicate messages

Definition at line 236 of file Sim.f90.

    ! -- dummy variables
    character(len=*), intent(in) :: msg !< warning message
    character(len=*), intent(in), optional :: substring !< optional string that can be used
                                                        !! to prevent storing duplicate messages
    !
    ! -- store warning
    if (present(substring)) then
      call sim_warnings%store(msg, substring)
    else
      call sim_warnings%store(msg)
    end if

Here is the caller graph for this function:

ustop()

subroutine, public simmodule::ustop	(	character, dimension (*), intent(in), optional	stopmess,
		integer(i4b), intent(in), optional	ioutlocal
	)

Subroutine to stop the simulations with option to print message before stopping with the active error code.

Parameters

[in]	stopmess	optional message to print before stopping the simulation
[in]	ioutlocal	optional output file to final message to

Definition at line 312 of file Sim.f90.

    ! -- dummy variables
    character, optional, intent(in) :: stopmess * (*) !< optional message to print before
                                                      !! stopping the simulation
    integer(I4B), optional, intent(in) :: ioutlocal !< optional output file to
                                                    !! final message to
    !
    ! -- print the final message
    call print_final_message(stopmess, ioutlocal)
    !
    ! -- terminate with the appropriate error code
    call pstop(ireturnerr)
 

Here is the call graph for this function:

Here is the caller graph for this function:

Variable Documentation

sim_errors

type(messagestype) simmodule::sim_errors

private

Definition at line 44 of file Sim.f90.

  type(MessagesType) :: sim_errors

sim_notes

type(messagestype) simmodule::sim_notes

private

Definition at line 47 of file Sim.f90.

  type(MessagesType) :: sim_notes

sim_uniterrors

type(messagestype) simmodule::sim_uniterrors

private

Definition at line 45 of file Sim.f90.

  type(MessagesType) :: sim_uniterrors

sim_warnings

type(messagestype) simmodule::sim_warnings

private

Definition at line 46 of file Sim.f90.

  type(MessagesType) :: sim_warnings