CellDefn.f90

Go to the documentation of this file.

module celldefnmodule
  use kindmodule, only: dp, i4b, lgp
  implicit none
 
  private
  public :: celldefntype
  public :: create_defn, get_iatop
  public :: saturation_dry, saturation_watertable, saturation_saturated
 
  !> @brief Cell saturation status.
  !!
  !! Status 0 indicates that the cell is dry.
  !! Status 1 indicates that the cell contains a water table.
  !! Since a water table might exist exactly at the top face,
  !! status 1 includes that case. Status 2 is reserved for a
  !! fully saturated cell with no water table.
  !<
  enum, bind(C)
    enumerator :: saturation_dry = 0
    enumerator :: saturation_watertable = 1
    enumerator :: saturation_saturated = 2
  end enum
 
  !> @brief Base grid cell definition.
  type celldefntype
    private
    integer(I4B), public :: icell !< index of cell in source grid
    logical(LGP), public :: can_be_rect !< whether cell is representable as a rectangular cell
    logical(LGP), public :: can_be_quad !< whether cell is representable as a rectangular quad cell
    integer(I4B), public :: npolyverts !< number of vertices for cell polygon
    real(dp), public :: porosity !< cell porosity
    real(dp), public :: retfactor !< cell retardation factor
    integer(I4B), public :: ilay !< layer number
    integer(I4B), public :: izone !< cell zone number
    integer(I4B), public :: iweaksink !< weak sink indicator
    integer(I4B), public :: inoexitface !< no exit face indicator
    integer(I4B), public :: iatop !< index of cell top in grid's top/bot arrays (<0 => top array)
    integer(I4B), public :: isatstat !< saturation status. 0 = dry, 1 = contains a water table, 2 = fully saturated w/ no water table
    real(dp), public :: top, bot !< top and bottom elevations of cell
    real(dp), public :: sat !< cell saturation
    real(dp), allocatable, public :: polyvert(:, :) !< vertices for cell polygon
    logical(LGP), allocatable, public :: ispv180(:) !< indicator of 180-degree vertices (.true. = 180-degree angle at vertex)
    integer(I4B), allocatable, public :: facenbr(:) !< neighbors that correspond to faces(/vertices)
    real(dp), allocatable, public :: faceflow(:) !< flows that correspond to faces(/vertices)
    real(dp), public :: distflow !< net distributed flow into cell
  contains
    procedure, public :: get_ispv180 !< returns 180-degree indicator for a vertex
    procedure, public :: get_botflow !< returns bottom flow
    procedure, public :: get_topflow !< returns top flow
    procedure, public :: get_distflow !< returns distributed flow
    procedure, public :: get_faceflow !< returns a face flow
  end type celldefntype
 
contains
 
  !> @brief Create a new cell definition object
  subroutine create_defn(cellDefn)
    type(celldefntype), pointer :: celldefn
    allocate (celldefn)
    ! Initially, allocate arrays to size for structured grid tracking method.
    ! They can be (lazily) expanded as necessary for the unstructured method.
    allocate (celldefn%ispv180(5))
    allocate (celldefn%facenbr(7))
    allocate (celldefn%faceflow(7))
  end subroutine create_defn
 
  !> @brief Get the index corresponding to top elevation of a cell in the grid.
  !! This is -1 if the cell is in the top layer and 1 otherwise.
  function get_iatop(ncpl, icu) result(iatop)
    integer(I4B), intent(in) :: ncpl, icu
    integer(I4B) :: iatop
 
    if (icu .le. ncpl) then
      iatop = -1
    else
      iatop = 1
    end if
  end function get_iatop
 
  !> @brief Return 180-degree indicator for a vertex
  function get_ispv180(this, m) result(ispv180)
    class(celldefntype), intent(inout) :: this
    integer(I4B) :: m
    logical(LGP) :: ispv180
    ispv180 = this%ispv180(m)
  end function get_ispv180
 
  !> @brief Return the bottom flow
  function get_botflow(this) result(botflow)
    class(celldefntype), intent(inout) :: this
    real(dp) :: botflow
    botflow = this%faceflow(this%npolyverts + 2)
  end function get_botflow
 
  !> @brief Return the top flow
  function get_topflow(this) result(topflow)
    class(celldefntype), intent(inout) :: this
    real(dp) :: topflow
    topflow = this%faceflow(this%npolyverts + 3)
  end function get_topflow
 
  !> @brief Return the distributed flow
  function get_distflow(this) result(distflow)
    class(celldefntype), intent(inout) :: this
    real(dp) :: distflow
    distflow = this%distflow
  end function get_distflow
 
  !> @brief Return a face flow
  function get_faceflow(this, m) result(faceflow)
    class(celldefntype), intent(inout) :: this
    integer(I4B) :: m
    real(dp) :: faceflow
    faceflow = this%faceflow(m)
  end function get_faceflow
 
end module celldefnmodule