NetCDFCommon.f90

Go to the documentation of this file.

!> @brief This module contains the NetCDFCommonModule
!!
!! Common NetCDF interfaces and constants
!!
!<
module netcdfcommonmodule
 
  use kindmodule, only: dp, i4b, lgp
  use constantsmodule, only: linelength
  use simvariablesmodule, only: errmsg
  use simmodule, only: store_error, store_error_filename
  use netcdf
 
  implicit none
  private
  public :: nc_fopen, nc_fclose
  public :: netcdf_max_dim
  public :: netcdf_attr_strlen
  public :: nf_verify
 
  integer(I4B), parameter :: netcdf_max_dim = 6
  integer(I4B), parameter :: netcdf_attr_strlen = 80
 
contains
 
  !> @brief Open netcdf file
  !<
  function nc_fopen(nc_fname, iout) result(ncid)
    character(len=*), intent(in) :: nc_fname
    integer(I4B), intent(in) :: iout
    ! -- return
    integer(I4B) :: ncid
    ! -- local
    !
    ! -- initialize
    ncid = -1
    !
    ! -- open netcdf file
    call nf_verify(nf90_open(nc_fname, nf90_nowrite, ncid), nc_fname)
  end function nc_fopen
 
  !> @brief Close netcdf file
  !<
  subroutine nc_fclose(ncid, nc_fname)
    integer(I4B), intent(in) :: ncid
    character(len=*), intent(in) :: nc_fname
    ! -- local
    !
    ! -- close netcdf file
    call nf_verify(nf90_close(ncid), nc_fname)
  end subroutine nc_fclose
 
  !> @brief error check a netcdf-fortran interface call
  !<
  subroutine nf_verify(res, nc_fname)
    integer(I4B), intent(in) :: res
    character(len=*), intent(in) :: nc_fname
    ! -- local variables
    character(len=LINELENGTH) :: errstr
    !
    ! -- strings are set for a subset of errors
    !    but the exit status will always be reported
    if (res /= nf90_noerr) then
      !
      select case (res)
      case (-33) ! (NC_EBADID)
        errstr = 'Not a netcdf id'
      case (nf90_einval) ! (-36)
        errstr = 'Invalid Argument'
      case (nf90_eperm) ! (-37)
        errstr = 'Write to read only'
      case (-38) ! (NC_ENOTINDEFINE)
        errstr = 'Operation not allowed in data mode'
      case (-39) ! (NC_EINDEFINE)
        errstr = 'Operation not allowed in define mode'
      case (nf90_einvalcoords) ! (-40)
        errstr = 'Index exceeds dimension bound'
      case (nf90_enameinuse) ! (-42)
        errstr = 'String match to name in use'
      case (nf90_enotatt) ! (-43)
        errstr = 'Attribute not found'
      case (-45) ! (NC_EBADTYPE)
        errstr = 'Not a netcdf data type'
      case (nf90_ebaddim) ! (-46)
        errstr = 'Invalid dimension id or name'
      case (nf90_enotvar) ! (-49)
        errstr = 'Variable not found'
      case (nf90_enotnc) ! (-51)
        errstr = 'Not a netcdf file'
      case (nf90_echar) ! (-56)
        errstr = 'Attempt to convert between text & numbers'
      case (nf90_eedge) ! (-57)
        errstr = 'Edge+start exceeds dimension bound'
      case (nf90_estride) ! (-58)
        errstr = 'Illegal stride'
      case (nf90_ebadname) ! (-59)
        errstr = 'Attribute or variable name contains illegal characters'
      case (-127) ! (NC_EBADCHUNK)
        errstr = 'Bad chunksize.'
      case default
        errstr = ''
      end select
      !
      if (errstr /= '') then
        write (errmsg, '(a,a,a,i0,a)') 'NetCDF library error [error="', &
          trim(errstr), '", exit code=', res, '].'
      else
        write (errmsg, '(a,i0,a)') 'NetCDF library error [exit code=', &
          res, '].'
      end if
      !
      call store_error(errmsg)
      call store_error_filename(nc_fname)
    end if
  end subroutine nf_verify
 
end module netcdfcommonmodule