defmacro.F90

Go to the documentation of this file.

module definedmacros
  ! -- modules
  use kindmodule, only: lgp, i4b
  use constantsmodule, only: osundef, oslinux, osmac, oswin
  implicit none
  private
  public :: get_os, is_extended, using_petsc, using_netcdf
contains
 
  !> @brief Get operating system
  !!
  !! Function to get the integer operating system enum value.
  !!
  !! @return      ios                operating system enum
  !<
  function get_os() result(ios)
    ! -- local variables
    integer(I4B) :: ios !< operating system
    !
    ! -- initialize ios
    ios = osundef
    !
    ! -- set operating system variables
#ifdef __GFORTRAN__
# ifdef __linux__
    ios = oslinux
# endif
# ifdef __APPLE__
    ios = osmac
# endif
# ifdef _WIN32
    ios = oswin
# endif
#endif
#ifdef __INTEL_COMPILER
# ifdef __linux__
    ios = oslinux
# endif
# ifdef __APPLE__
    ios = osmac
# endif
# ifdef _WIN32
    ios = oswin
# endif
#endif
    !
  end function get_os
 
  !> @brief Determine if this is the extended version
  !!
  !! Function to get a logical indicating if this is the
  !! extended version of MODFLOW.
  !!
  !! @return      isextended           extended version logical
  !<
  function is_extended() result(isextended)
    ! -- return variables
    logical(LGP) :: isextended !< extended version logical
    ! -- local variables
    logical(LGP) :: ispetsc
    logical(LGP) :: isnetcdf
    !
    ! -- initialize isextended
    isextended = .false.
    !
    ! -- check if using petsc
    ispetsc = using_petsc()
    !
    ! -- check if using netcf
    isnetcdf = using_netcdf()
    !
    !
    if (ispetsc .EQV. .true. .OR. isnetcdf .EQV. .true.) then
      isextended = .true.
    end if
    !
  end function is_extended
 
  !> @brief Determine if using petsc
  !!
  !! Function to get a logical indicating if petsc is
  !! being used.
  !!
  !! @return      petscused                petsc used logical
  !<
  function using_petsc() result(petscused)
    ! -- return variable
    logical(LGP) :: petscused !< petsc used logical
    !
    ! -- initialize petscavail
    petscused = .false.
    !
    ! -- set operating system variables
#ifdef __WITH_PETSC__
    petscused = .true.
#endif
    !
  end function using_petsc
 
  !> @brief Determine if using netcdf
  !!
  !! Function to get a logical indicating if netcdf is
  !! being used.
  !!
  !! @return      netcdfused                netcdf used logical
  !<
  function using_netcdf() result(netcdfused)
    ! -- return variable
    logical(LGP) :: netcdfused !< netcdf used logical
    !
    ! -- initialize petscavail
    netcdfused = .false.
    !
    ! -- set operating system variables
#ifdef __WITH_NETCDF__
    netcdfused = .true.
#endif
    !
  end function using_netcdf
 
end module definedmacros