timermodule Module Reference

Functions/Subroutines
subroutine, public	print_start_time ()
	Start simulation timer. More...
subroutine, public	elapsed_time (iout, iprtim)
	Get end time and calculate elapsed time. More...
subroutine, public	code_timer (it, t1, ts)
	Get end time and calculate elapsed time. More...

Variables
integer(i4b), dimension(8)	ibdt

Function/Subroutine Documentation

code_timer()

subroutine, public timermodule::code_timer	(	integer(i4b), intent(in)	it,
		real(dp), intent(inout)	t1,
		real(dp), intent(inout)	ts
	)

Timer for subroutines

Definition at line 158 of file Timer.f90.

    ! -- dummy
    integer(I4B), intent(in) :: it
    real(DP), intent(inout) :: t1
    real(DP), intent(inout) :: ts
    ! -- local
    real(DP) :: dt
    !
    if (it == 0) then
      call cpu_time(t1)
    else
      call cpu_time(dt)
      ts = ts + dt - t1
    end if

Here is the caller graph for this function:

elapsed_time()

subroutine, public timermodule::elapsed_time	(	integer(i4b), intent(in)	iout,
		integer(i4b), intent(in)	iprtim
	)

Definition at line 35 of file Timer.f90.

    ! -- dummy
    integer(I4B), intent(in) :: iout
    integer(I4B), intent(in) :: iprtim
    ! -- local
    character(len=LINELENGTH) :: line
    integer(I4B) :: IEDT(8), IDPM(12)
    integer(I4B) :: NSPD
    integer(I4B) :: i
    integer(I4B) :: ndays, leap, ibd, ied, mb, me, nm, mc, m
    integer(I4B) :: nhours, nmins, nsecs, msecs, nrsecs
    real(DP) :: elsec, rsecs
    data idpm/31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31/ !< Days per month
    data nspd/86400/ !< Seconds per day
    ! -- formats
    character(len=*), parameter :: fmtdt = &
      "(1x,'Run end date and time (yyyy/mm/dd hh:mm:ss): ', &
      &I4,'/',I2.2,'/',I2.2,1x,I2,':',I2.2,':',I2.2)"
    character(len=*), parameter :: fmttma = &
      "(1x,'Elapsed run time: ',I3,' Days, ',I2,' Hours, ',I2, &
      &' Minutes, ', I2, ' Seconds')"
    character(len=*), parameter :: fmttmb = &
      &"(1x,'Elapsed run time: ',I2,' Hours, ',I2,' Minutes, ',I2,' Seconds')"
    character(len=*), parameter :: fmttmc = &
      &"(1x,'Elapsed run time: ',I2,' Minutes, ',I2,'.',I3.3,' Seconds')"
    character(len=*), parameter :: fmttmd = &
      &"(1x,'Elapsed run time: ',I2,'.',I3.3,' Seconds')"
    !
    ! -- Get current date and time, assign to IEDT, and write.
    call date_and_time(values=iedt)
    !
    ! -- Write elapsed time to stdout
    write (line, fmtdt) (iedt(i), i=1, 3), (iedt(i), i=5, 7)
    call write_message(line, skipbefore=1)
    !
    ! -- Write elapsted time to iout
    if (iprtim > 0) then
      call write_message(line, iunit=iout, skipbefore=1)
    end if
    !
    ! -- Calculate elapsed time in days and seconds
    ndays = 0
    leap = 0
    if (mod(iedt(1), 4) == 0) leap = 1
    ibd = ibdt(3) !< Begin Day
    ied = iedt(3) !< End Day
    !
    ! -- Find days
    if (ibdt(2) /= iedt(2)) then
      ! -- Months differ
      mb = ibdt(2) !< Begin month
      me = iedt(2) !< End month
      nm = me - mb + 1 !< Number of months to look at
      if (mb > me) nm = nm + 12
      mc = mb - 1
      do m = 1, nm
        mc = mc + 1 !< mc is current month
        if (mc == 13) mc = 1
        if (mc == mb) then
          ndays = ndays + idpm(mc) - ibd
          if (mc == 2) ndays = ndays + leap
        elseif (mc == me) then
          ndays = ndays + ied
        else
          ndays = ndays + idpm(mc)
          if (mc == 2) ndays = ndays + leap
        end if
      end do
    elseif (ibd < ied) then
      ! -- Start and end in same month, only account for days
      ndays = ied - ibd
    end if
    elsec = ndays * nspd
    !
    ! -- Add or subtract seconds
    elsec = elsec + (iedt(5) - ibdt(5)) * 3600.0
    elsec = elsec + (iedt(6) - ibdt(6)) * 60.0
    elsec = elsec + (iedt(7) - ibdt(7))
    elsec = elsec + (iedt(8) - ibdt(8)) * 0.001
    !
    ! -- Convert seconds to days, hours, minutes, and seconds
    ndays = int(elsec / nspd)
    rsecs = mod(elsec, dsecperdy)
    nhours = int(rsecs / 3600.0)
    rsecs = mod(rsecs, dsecperhr)
    nmins = int(rsecs / 60.0)
    rsecs = mod(rsecs, dsixty)
    nsecs = int(rsecs)
    rsecs = mod(rsecs, done)
    msecs = nint(rsecs * 1000.0)
    nrsecs = nsecs
    if (rsecs > 0.5) nrsecs = nrsecs + 1
    !
    ! -- Write elapsed time to screen
    if (ndays > 0) then
      write (line, fmttma) ndays, nhours, nmins, nrsecs
    elseif (nhours > 0) then
      write (line, fmttmb) nhours, nmins, nrsecs
    elseif (nmins > 0) then
      write (line, fmttmc) nmins, nsecs, msecs
    else
      write (line, fmttmd) nsecs, msecs
    end if
    call write_message(line, skipafter=1)
    !
    ! -- Write times to file if requested
    if (iprtim > 0) then
      IF (ndays > 0) THEN
        WRITE (iout, fmttma) ndays, nhours, nmins, nrsecs
      ELSEIF (nhours > 0) THEN
        WRITE (iout, fmttmb) nhours, nmins, nrsecs
      ELSEIF (nmins > 0) THEN
        WRITE (iout, fmttmc) nmins, nsecs, msecs
      ELSE
        WRITE (iout, fmttmd) nsecs, msecs
      END IF
    END IF

Here is the call graph for this function:

Here is the caller graph for this function:

print_start_time()

subroutine, public timermodule::print_start_time

Definition at line 18 of file Timer.f90.

    ! -- local
    character(len=LINELENGTH) :: line
    integer(I4B) :: i
    ! -- formats
    character(len=*), parameter :: fmtdt = &
      "(1X,'Run start date and time (yyyy/mm/dd hh:mm:ss): ', &
      &I4,'/',I2.2,'/',I2.2,1X,I2,':',I2.2,':',I2.2)"
    !
    ! -- Get current date and time, assign to IBDT, and write to screen
    call date_and_time(values=ibdt)
    write (line, fmtdt) (ibdt(i), i=1, 3), (ibdt(i), i=5, 7)
    call write_message(line, skipafter=1)

Here is the call graph for this function:

Here is the caller graph for this function:

Variable Documentation

ibdt

integer(i4b), dimension(8) timermodule::ibdt

private

Definition at line 12 of file Timer.f90.

  integer(I4B), dimension(8) :: ibdt