TimeSeriesManager.f90

Go to the documentation of this file.

module timeseriesmanagermodule
 
  use kindmodule, only: dp, i4b
  use constantsmodule, only: dzero, lenpackagename, maxcharlen, &
                             linelength, lentimeseriesname
  use hashtablemodule, only: hashtabletype, hash_table_cr, &
                             hash_table_da
  use inputoutputmodule, only: same_word, upcase
  use listmodule, only: listtype
  use simmodule, only: store_error, store_error_unit
  use tdismodule, only: delt, kper, kstp, totim, totimc, &
                        totimsav
  use timeseriesfilelistmodule, only: timeseriesfilelisttype
  use timeserieslinkmodule, only: timeserieslinktype, &
                                  constructtimeserieslink, &
                                  gettimeserieslinkfromlist, &
                                  addtimeserieslinktolist
  use timeseriesmodule, only: timeseriescontainertype, &
                              timeseriesfiletype, &
                              timeseriestype
 
  implicit none
 
  private
  public :: timeseriesmanagertype, read_value_or_time_series, &
            read_value_or_time_series_adv, &
            var_timeseries, tsmanager_cr
 
  type timeseriesmanagertype
    integer(I4B), public :: iout = 0 ! output unit number
    type(timeseriesfilelisttype), pointer, public :: tsfilelist => null() ! list of ts files objs
    type(listtype), pointer, public :: boundtslinks => null() ! links to bound and aux
    integer(I4B) :: numtsfiles = 0 ! number of ts files
    character(len=MAXCHARLEN), allocatable, dimension(:) :: tsfiles ! list of ts files
    logical, private :: removetslinksoncompletion = .false. ! flag indicating whether time series links should be removed in ad() once simulation time passes the end of the time series
    logical, private :: extendtstoendofsimulation = .false. ! flag indicating whether time series should be extended to provide their final value for all times after the series end time
    type(listtype), pointer, private :: auxvartslinks => null() ! list of aux links
    type(hashtabletype), pointer, private :: bndtshashtable => null() ! hash of ts to tsobj
    type(timeseriescontainertype), allocatable, dimension(:), &
      private :: tscontainers
 
  contains
 
    ! -- Public procedures
    procedure, public :: tsmanager_df
    procedure, public :: ad => tsmgr_ad
    procedure, public :: da => tsmgr_da
    procedure, public :: add_tsfile
    procedure, public :: countlinks
    procedure, public :: getlink
    procedure, public :: reset
    procedure, public :: hashbndtimeseries
    ! -- Private procedures
    procedure, private :: get_time_series
    procedure, private :: make_link
  end type timeseriesmanagertype
 
contains
 
  !> @brief Create the tsmanager
  !<
  subroutine tsmanager_cr(this, iout, removeTsLinksOnCompletion, &
                          extendTsToEndOfSimulation)
    ! -- dummy
    type(timeseriesmanagertype) :: this
    integer(I4B), intent(in) :: iout
    logical, intent(in), optional :: removetslinksoncompletion
    logical, intent(in), optional :: extendtstoendofsimulation
    !
    this%iout = iout
    if (present(removetslinksoncompletion)) then
      this%removeTsLinksOnCompletion = removetslinksoncompletion
    end if
    if (present(extendtstoendofsimulation)) then
      this%extendTsToEndOfSimulation = extendtstoendofsimulation
    end if
    allocate (this%boundTsLinks)
    allocate (this%auxvarTsLinks)
    allocate (this%tsfileList)
    allocate (this%tsfiles(1000))
  end subroutine tsmanager_cr
 
  !> @brief Define time series manager object
  !<
  subroutine tsmanager_df(this)
    ! -- dummy
    class(timeseriesmanagertype) :: this
    !
    if (this%numtsfiles > 0) then
      call this%HashBndTimeSeries()
    end if
  end subroutine tsmanager_df
 
  !> @brief Add a time series file to this manager
  !<
  subroutine add_tsfile(this, fname, inunit)
    ! -- modules
    use simmodule, only: store_error, store_error_unit
    use arrayhandlersmodule, only: expandarray
    ! -- dummy
    class(timeseriesmanagertype) :: this
    character(len=*), intent(in) :: fname
    integer(I4B), intent(in) :: inunit
    ! -- local
    integer(I4B) :: isize
    integer(I4B) :: i
    class(timeseriesfiletype), pointer :: tsfile => null()
    !
    ! -- Check for fname duplicates
    if (this%numtsfiles > 0) then
      do i = 1, this%numtsfiles
        if (this%tsfiles(i) == fname) then
          call store_error('Found duplicate time-series file name: '//trim(fname))
          call store_error_unit(inunit)
        end if
      end do
    end if
    !
    ! -- Save fname
    this%numtsfiles = this%numtsfiles + 1
    isize = size(this%tsfiles)
    if (this%numtsfiles > isize) then
      call expandarray(this%tsfiles, 1000)
    end if
    this%tsfiles(this%numtsfiles) = fname
    !
    ! --
    call this%tsfileList%Add(fname, this%iout, tsfile)
  end subroutine add_tsfile
 
  !> @brief Time step (or subtime step) advance. Call this each time step or
  !! subtime step
  !<
  subroutine tsmgr_ad(this)
    ! -- dummy
    class(timeseriesmanagertype) :: this
    ! -- local
    type(timeserieslinktype), pointer :: tsLink => null()
    type(timeseriestype), pointer :: timeseries => null()
    integer(I4B) :: i, nlinks, nauxlinks
    real(DP) :: begintime, endtime, tsendtime
    character(len=LENPACKAGENAME + 2) :: pkgID
    ! -- formats
    character(len=*), parameter :: fmt5 = &
      "(/,'Time-series controlled values in stress period: ', i0, &
      &', time step ', i0, ':')"
10  format(a, ' package: Boundary ', i0, ', entry ', i0, &
           ' value from time series "', a, '" = ', g12.5)
15  format(a, ' package: Boundary ', i0, ', entry ', i0, &
           ' value from time series "', a, '" = ', g12.5, ' (', a, ')')
20  format(a, ' package: Boundary ', i0, ', ', a, &
           ' value from time series "', a, '" = ', g12.5)
25  format(a, ' package: Boundary ', i0, ', ', a, &
           ' value from time series "', a, '" = ', g12.5, ' (', a, ')')
    !
    ! -- Initialize time variables
    begintime = totimc
    endtime = begintime + delt
    !
    ! -- Determine number of ts links
    nlinks = this%boundtslinks%Count()
    nauxlinks = this%auxvartslinks%Count()
    !
    ! -- Iterate through auxvartslinks and replace specified
    !    elements of auxvar with average value obtained from
    !    appropriate time series.  Need to do auxvartslinks
    !    first because they may be a multiplier column
    i = 1
    do while (i <= nauxlinks)
      tslink => gettimeserieslinkfromlist(this%auxvarTsLinks, i)
      timeseries => tslink%timeSeries
      !
      ! -- Remove time series link once its end time has passed, if requested
      if (this%removeTsLinksOnCompletion) then
        tsendtime = timeseries%FindLatestTime(.true.)
        if (tsendtime < begintime) then
          call this%auxvarTsLinks%RemoveNode(i, .true.)
          nauxlinks = this%auxvartslinks%Count()
          cycle
        end if
      end if
      !
      if (i == 1) then
        if (tslink%Iprpak == 1) then
          write (this%iout, fmt5) kper, kstp
        end if
      end if
      tslink%BndElement = timeseries%GetValue(begintime, endtime, &
                                              this%extendTsToEndOfSimulation)
      !
      ! -- Write time series values to output file
      if (tslink%Iprpak == 1) then
        pkgid = '"'//trim(tslink%PackageName)//'"'
        if (tslink%Text == '') then
          if (tslink%BndName == '') then
            write (this%iout, 10) trim(pkgid), tslink%IRow, tslink%JCol, &
              trim(tslink%timeSeries%Name), &
              tslink%BndElement
          else
            write (this%iout, 15) trim(pkgid), tslink%IRow, tslink%JCol, &
              trim(tslink%timeSeries%Name), &
              tslink%BndElement, trim(tslink%BndName)
          end if
        else
          if (tslink%BndName == '') then
            write (this%iout, 20) trim(pkgid), tslink%IRow, trim(tslink%Text), &
              trim(tslink%timeSeries%Name), &
              tslink%BndElement
          else
            write (this%iout, 25) trim(pkgid), tslink%IRow, trim(tslink%Text), &
              trim(tslink%timeSeries%Name), &
              tslink%BndElement, trim(tslink%BndName)
          end if
        end if
      end if
      !
      i = i + 1
    end do
    !
    ! -- Iterate through boundtslinks and replace specified
    !    elements of bound with average value obtained from
    !    appropriate time series. (For list-type packages)
    i = 1
    do while (i <= nlinks)
      tslink => gettimeserieslinkfromlist(this%boundTsLinks, i)
      timeseries => tslink%timeSeries
      !
      ! -- Remove time series link once its end time has passed, if requested
      if (this%removeTsLinksOnCompletion) then
        tsendtime = timeseries%FindLatestTime(.true.)
        if (tsendtime < begintime) then
          call this%boundTsLinks%RemoveNode(i, .true.)
          nlinks = this%boundTsLinks%Count()
          cycle
        end if
      end if
      !
      if (i == 1 .and. nauxlinks == 0) then
        if (tslink%Iprpak == 1) then
          write (this%iout, fmt5) kper, kstp
        end if
      end if
      ! this part needs to be different for MAW because MAW does not use
      ! bound array for well rate (although rate is stored in
      ! this%bound(4,ibnd)), it uses this%mawwells(n)%rate%value
      if (tslink%UseDefaultProc) then
        timeseries => tslink%timeSeries
        tslink%BndElement = timeseries%GetValue(begintime, endtime, &
                                                this%extendTsToEndOfSimulation)
        !
        ! -- If multiplier is active and it applies to this element,
        !    do the multiplication.  This must be done after the auxlinks
        !    have been calculated in case iauxmultcol is being used.
        if (associated(tslink%RMultiplier)) then
          tslink%BndElement = tslink%BndElement * tslink%RMultiplier
        end if
        !
        ! -- Write time series values to output files
        if (tslink%Iprpak == 1) then
          pkgid = '"'//trim(tslink%PackageName)//'"'
          if (tslink%Text == '') then
            if (tslink%BndName == '') then
              write (this%iout, 10) trim(pkgid), tslink%IRow, tslink%JCol, &
                trim(tslink%timeSeries%Name), &
                tslink%BndElement
            else
              write (this%iout, 15) trim(pkgid), tslink%IRow, tslink%JCol, &
                trim(tslink%timeSeries%Name), &
                tslink%BndElement, trim(tslink%BndName)
            end if
          else
            if (tslink%BndName == '') then
              write (this%iout, 20) trim(pkgid), tslink%IRow, trim(tslink%Text), &
                trim(tslink%timeSeries%Name), &
                tslink%BndElement
            else
              write (this%iout, 25) trim(pkgid), tslink%IRow, trim(tslink%Text), &
                trim(tslink%timeSeries%Name), &
                tslink%BndElement, trim(tslink%BndName)
            end if
          end if
        end if
        !
        ! -- If conversion from flux to flow is required, multiply by cell area
        if (tslink%ConvertFlux) then
          tslink%BndElement = tslink%BndElement * tslink%CellArea
        end if
      end if
      !
      i = i + 1
    end do
    !
    ! -- Finish with ending line
    if (nlinks + nauxlinks > 0) then
      if (tslink%Iprpak == 1) then
        write (this%iout, '()')
      end if
    end if
  end subroutine tsmgr_ad
 
  !> @brief Deallocate memory
  !<
  subroutine tsmgr_da(this)
    ! -- dummy
    class(timeseriesmanagertype) :: this
    ! -- local
    !
    ! -- Deallocate time-series links in boundTsLinks
    call this%boundTsLinks%Clear(.true.)
    deallocate (this%boundTsLinks)
    !
    ! -- Deallocate time-series links in auxvarTsLinks
    call this%auxvarTsLinks%Clear(.true.)
    deallocate (this%auxvarTsLinks)
    !
    ! -- Deallocate tsfileList
    call this%tsfileList%da()
    deallocate (this%tsfileList)
    !
    ! -- Deallocate the hash table
    if (associated(this%BndTsHashTable)) then
      call hash_table_da(this%BndTsHashTable)
    end if
    !
    deallocate (this%tsfiles)
  end subroutine tsmgr_da
 
  !> @brief Call this when a new BEGIN PERIOD block is read for a new stress
  !! period
  !<
  subroutine reset(this, pkgName)
    ! -- dummy
    class(timeseriesmanagertype) :: this
    character(len=*), intent(in) :: pkgName
    ! -- local
    integer(I4B) :: i, nlinks
    type(timeserieslinktype), pointer :: tslink
    !
    ! Zero out values for time-series controlled stresses.
    ! Also deallocate all tslinks too.
    ! Then when time series are
    ! specified in this or another stress period,
    ! a new tslink would be set up.
    !
    ! Reassign all linked elements to zero
    nlinks = this%boundTsLinks%Count()
    do i = 1, nlinks
      tslink => gettimeserieslinkfromlist(this%boundTsLinks, i)
      if (associated(tslink)) then
        if (tslink%PackageName == pkgname) then
          tslink%BndElement = dzero
        end if
      end if
    end do
    !
    ! Remove links belonging to calling package
    nlinks = this%boundTsLinks%Count()
    do i = nlinks, 1, -1
      tslink => gettimeserieslinkfromlist(this%boundTsLinks, i)
      if (associated(tslink)) then
        if (tslink%PackageName == pkgname) then
          call this%boundTsLinks%RemoveNode(i, .true.)
        end if
      end if
    end do
    nlinks = this%auxvarTsLinks%Count()
    do i = nlinks, 1, -1
      tslink => gettimeserieslinkfromlist(this%auxvarTsLinks, i)
      if (associated(tslink)) then
        if (tslink%PackageName == pkgname) then
          call this%auxvarTsLinks%RemoveNode(i, .true.)
        end if
      end if
    end do
  end subroutine reset
 
  !> @brief Make link
  !<
  subroutine make_link(this, timeSeries, pkgName, auxOrBnd, bndElem, &
                       irow, jcol, iprpak, tsLink, text, bndName)
    ! -- dummy
    class(timeseriesmanagertype), intent(inout) :: this
    type(timeseriestype), pointer, intent(inout) :: timeSeries
    character(len=*), intent(in) :: pkgName
    character(len=3), intent(in) :: auxOrBnd
    real(DP), pointer, intent(inout) :: bndElem
    integer(I4B), intent(in) :: irow, jcol
    integer(I4B), intent(in) :: iprpak
    type(timeserieslinktype), pointer, intent(inout) :: tsLink
    character(len=*), intent(in) :: text
    character(len=*), intent(in) :: bndName
    !
    tslink => null()
    call constructtimeserieslink(tslink, timeseries, pkgname, &
                                 auxorbnd, bndelem, irow, jcol, iprpak)
    if (associated(tslink)) then
      if (auxorbnd == 'BND') then
        call addtimeserieslinktolist(this%boundTsLinks, tslink)
      elseif (auxorbnd == 'AUX') then
        call addtimeserieslinktolist(this%auxvarTsLinks, tslink)
      else
        call store_error('programmer error in make_link', terminate=.true.)
      end if
      tslink%Text = text
      tslink%BndName = bndname
    end if
  end subroutine make_link
 
  !> @brief Get link
  !<
  function getlink(this, auxOrBnd, indx) result(tsLink)
    ! -- dummy
    class(timeseriesmanagertype) :: this
    character(len=3), intent(in) :: auxorbnd
    integer(I4B), intent(in) :: indx
    type(timeserieslinktype), pointer :: tslink
    ! -- local
    type(listtype), pointer :: list
    !
    list => null()
    tslink => null()
    !
    select case (auxorbnd)
    case ('AUX')
      list => this%auxvarTsLinks
    case ('BND')
      list => this%boundTsLinks
    end select
    !
    if (associated(list)) then
      tslink => gettimeserieslinkfromlist(list, indx)
    end if
  end function getlink
 
  !> @brief Count links
  !<
  function countlinks(this, auxOrBnd)
    ! -- return
    integer(I4B) :: countlinks
    ! -- dummy
    class(timeseriesmanagertype) :: this
    character(len=3), intent(in) :: auxorbnd
    !
    countlinks = 0
    if (auxorbnd == 'BND') then
      countlinks = this%boundTsLinks%Count()
    elseif (auxorbnd == 'AUX') then
      countlinks = this%auxvarTsLinks%count()
    end if
  end function countlinks
 
  !> @brief Get time series
  !<
  function get_time_series(this, name) result(res)
    ! -- dummy
    class(timeseriesmanagertype) :: this
    character(len=*), intent(in) :: name
    ! -- result
    type(timeseriestype), pointer :: res
    ! -- local
    integer(I4B) :: indx
    !
    ! Get index from hash table, get time series from TsContainers,
    !     and assign result to time series contained in link.
    res => null()
    indx = this%BndTsHashTable%get(name)
    if (indx > 0) then
      res => this%TsContainers(indx)%timeSeries
    end if
  end function get_time_series
 
  !> @brief Store all boundary (stress) time series links in TsContainers
  !! and construct hash table BndTsHashTable
  !<
  subroutine hashbndtimeseries(this)
    ! -- dummy
    class(timeseriesmanagertype), intent(inout) :: this
    ! -- local
    integer(I4B) :: i, j, k, numtsfiles, numts
    character(len=LENTIMESERIESNAME) :: name
    type(timeseriesfiletype), pointer :: tsfile => null()
    !
    ! Initialize the hash table
    call hash_table_cr(this%BndTsHashTable)
    !
    ! Allocate the TsContainers array to accommodate all time-series links.
    numts = this%tsfileList%CountTimeSeries()
    allocate (this%TsContainers(numts))
    !
    ! Store a pointer to each time series in the TsContainers array
    ! and put its key (time-series name) and index in the hash table.
    numtsfiles = this%tsfileList%Counttsfiles()
    k = 0
    do i = 1, numtsfiles
      tsfile => this%tsfileList%Gettsfile(i)
      numts = tsfile%Count()
      do j = 1, numts
        k = k + 1
        this%TsContainers(k)%timeSeries => tsfile%GetTimeSeries(j)
        if (associated(this%TsContainers(k)%timeSeries)) then
          name = this%TsContainers(k)%timeSeries%Name
          call this%BndTsHashTable%add(name, k)
        end if
      end do
    end do
  end subroutine hashbndtimeseries
 
  ! -- Non-type-bound procedures
 
  !> @brief Call this subroutine if the time-series link is available or needed
  !!
  !! This routine assumes that there is not an existing link for the
  !! specified package and array row and column.  For the standard
  !! boundary package, all links are removed by calling the tsmanager%reset()
  !! method.  For advanced packages, there is a separate routine called
  !! read_value_or_time_series_adv, which should be used instead of this one.
  !<
  subroutine read_value_or_time_series(textInput, ii, jj, bndElem, pkgName, &
                                       auxOrBnd, tsManager, iprpak, tsLink)
    ! dummy
    character(len=*), intent(in) :: textinput
    integer(I4B), intent(in) :: ii
    integer(I4B), intent(in) :: jj
    real(dp), pointer, intent(inout) :: bndelem
    character(len=*), intent(in) :: pkgname
    character(len=3), intent(in) :: auxorbnd
    type(timeseriesmanagertype), intent(inout) :: tsmanager
    integer(I4B), intent(in) :: iprpak
    type(timeserieslinktype), pointer, intent(inout) :: tslink
    ! local
    type(timeseriestype), pointer :: timeseries => null()
    integer(I4B) :: istat
    real(dp) :: r
    character(len=LINELENGTH) :: errmsg
    character(len=LENTIMESERIESNAME) :: tsnametemp
 
    read (textinput, *, iostat=istat) r
    if (istat == 0) then
      bndelem = r
    else
 
      ! Check to see if this is a time series name
      tsnametemp = textinput
      call upcase(tsnametemp)
      timeseries => tsmanager%get_time_series(tsnametemp)
 
      ! If this is a time series, then create a link between
      ! the time series and the row and column position of
      ! bndElem
      if (associated(timeseries)) then
        ! -- Assign value from time series to current
        !    array element
        r = timeseries%GetValue(totimsav, totim, &
                                tsmanager%extendTsToEndOfSimulation)
        bndelem = r
        ! Make a new link between the time series and the row and
        ! column position in the array
        call tsmanager%make_link(timeseries, pkgname, auxorbnd, bndelem, &
                                 ii, jj, iprpak, tslink, '', '')
      else
        errmsg = 'Error in list input. Expected numeric value or '// &
                 "time-series name, but found '"//trim(textinput)//"'."
        call store_error(errmsg)
      end if
    end if
 
  end subroutine read_value_or_time_series
 
  !> @brief Call this subroutine from advanced packages to define timeseries
  !! link for a variable (varName).
  !!
  !! Arguments are as follows:
  !!    textInput    : string that is either a float or a string name
  !!    ii           : column number
  !!    jj           : row number
  !!    bndElem      : pointer to a position in an array in package pkgName
  !!    pkgName      : package name
  !!    auxOrBnd     : 'AUX' or 'BND' keyword
  !!    tsManager    : timeseries manager object for package
  !!    iprpak       : integer flag indicating if interpolated timeseries values
  !!                   should be printed to package iout during TsManager%ad()
  !!    varName      : variable name
  !<
  subroutine read_value_or_time_series_adv(textInput, ii, jj, bndElem, pkgName, &
                                           auxOrBnd, tsManager, iprpak, varName)
    ! -- dummy
    character(len=*), intent(in) :: textinput
    integer(I4B), intent(in) :: ii
    integer(I4B), intent(in) :: jj
    real(dp), pointer, intent(inout) :: bndelem
    character(len=*), intent(in) :: pkgname
    character(len=3), intent(in) :: auxorbnd
    type(timeseriesmanagertype), intent(inout) :: tsmanager
    integer(I4B), intent(in) :: iprpak
    character(len=*), intent(in) :: varname
    ! -- local
    integer(I4B) :: istat
    real(dp) :: v
    character(len=LINELENGTH) :: errmsg
    character(len=LENTIMESERIESNAME) :: tsnametemp
    logical :: found
    type(timeseriestype), pointer :: timeseries => null()
    type(timeserieslinktype), pointer :: tslink => null()
    !
    ! -- attempt to read textInput as a real value
    read (textinput, *, iostat=istat) v
    !
    ! -- numeric value
    if (istat == 0) then
      !
      ! -- Numeric value was successfully read.
      bndelem = v
      !
      ! -- remove existing link if it exists for this boundary element
      found = remove_existing_link(tsmanager, ii, jj, pkgname, &
                                   auxorbnd, varname)
      !
      ! -- timeseries
    else
      !
      ! -- attempt to read numeric value from textInput failed.
      !    Text should be a time-series name.
      tsnametemp = textinput
      call upcase(tsnametemp)
      !
      ! -- if textInput is a time-series name, get average value
      !    from time series.
      timeseries => tsmanager%get_time_series(tsnametemp)
      !
      ! -- create a time series link and add it to the package
      !    list of time series links used by the array.
      if (associated(timeseries)) then
        !
        ! -- Assign average value from time series to current array element
        v = timeseries%GetValue(totimsav, totim, &
                                tsmanager%extendTsToEndOfSimulation)
        bndelem = v
        !
        ! -- remove existing link if it exists for this boundary element
        found = remove_existing_link(tsmanager, ii, jj, &
                                     pkgname, auxorbnd, varname)
        !
        ! -- Add link to the list.
        call tsmanager%make_link(timeseries, pkgname, auxorbnd, bndelem, &
                                 ii, jj, iprpak, tslink, varname, '')
        !
        ! -- not a valid timeseries name
      else
        errmsg = 'Error in list input. Expected numeric value or '// &
                 "time-series name, but found '"//trim(textinput)//"'."
        call store_error(errmsg)
      end if
    end if
  end subroutine read_value_or_time_series_adv
 
! -- private subroutines
 
  !> @brief Remove an existing timeseries link if it is defined.
  !!
  !! Arguments are as follows:
  !!    tsManager    : timeseries manager object for package
  !!    ii           : column number
  !!    jj           : row number
  !!    pkgName      : package name
  !!    auxOrBnd     : 'AUX' or 'BND' keyword
  !!    varName      : variable name
  !<
  function remove_existing_link(tsManager, ii, jj, &
                                pkgName, auxOrBnd, varName) result(found)
    ! -- return
    logical :: found
    ! -- dummy
    type(timeseriesmanagertype), intent(inout) :: tsmanager
    integer(I4B), intent(in) :: ii
    integer(I4B), intent(in) :: jj
    character(len=*), intent(in) :: pkgname
    character(len=3), intent(in) :: auxorbnd
    character(len=*), intent(in) :: varname
    ! -- local
    integer(I4B) :: i
    integer(I4B) :: nlinks
    integer(I4B) :: removelink
    type(timeserieslinktype), pointer :: tsltemp => null()
    !
    ! -- determine if link exists
    nlinks = tsmanager%CountLinks(auxorbnd)
    found = .false.
    removelink = -1
    csearchlinks: do i = 1, nlinks
      tsltemp => tsmanager%GetLink(auxorbnd, i)
      !
      ! -- Check ii against iRow, jj against jCol, and varName
      !    against Text member of link
      if (tsltemp%PackageName == pkgname) then
        !
        ! -- This array element is already linked to a time series.
        if (tsltemp%IRow == ii .and. tsltemp%JCol == jj .and. &
            same_word(tsltemp%Text, varname)) then
          found = .true.
          removelink = i
          exit csearchlinks
        end if
      end if
    end do csearchlinks
    !
    ! -- remove link if it was found
    if (removelink > 0) then
      if (auxorbnd == 'BND') then
        call tsmanager%boundTsLinks%RemoveNode(removelink, .true.)
      else if (auxorbnd == 'AUX') then
        call tsmanager%auxvarTsLinks%RemoveNode(removelink, .true.)
      end if
    end if
  end function remove_existing_link
 
  !> @brief Determine if a timeseries link with varName is defined.
  !!
  !! Arguments are as follows:
  !!    tsManager    : timeseries manager object for package
  !!    pkgName      : package name
  !!    varName      : variable name
  !!    auxOrBnd     : optional 'AUX' or 'BND' keyword
  !<
  function var_timeseries(tsManager, pkgName, varName, auxOrBnd) result(tsexists)
    ! -- return
    logical :: tsexists
    ! -- dummy
    type(timeseriesmanagertype), intent(inout) :: tsmanager
    character(len=*), intent(in) :: pkgname
    character(len=*), intent(in) :: varname
    character(len=3), intent(in), optional :: auxorbnd
    ! -- local
    character(len=3) :: ctstype
    integer(I4B) :: i
    integer(I4B) :: nlinks
    type(timeserieslinktype), pointer :: tsltemp => null()
    !
    ! -- process optional variables
    if (present(auxorbnd)) then
      ctstype = auxorbnd
    else
      ctstype = 'BND'
    end if
    !
    ! -- initialize the return variable and the number of timeseries links
    tsexists = .false.
    nlinks = tsmanager%CountLinks(ctstype)
    !
    ! -- determine if link exists
    csearchlinks: do i = 1, nlinks
      tsltemp => tsmanager%GetLink(ctstype, i)
      if (tsltemp%PackageName == pkgname) then
        !
        ! -- Check varName against Text member of link
        if (same_word(tsltemp%Text, varname)) then
          tsexists = .true.
          exit csearchlinks
        end if
      end if
    end do csearchlinks
  end function var_timeseries
 
end module timeseriesmanagermodule