Data Types
type	gwtmodeltype

Functions/Subroutines
subroutine, public	gwt_cr (filename, id, modelname)
	Create a new groundwater transport model object. More...

subroutine	gwt_df (this)
	Define packages of the GWT model. More...

subroutine	gwt_ac (this, sparse)
	Add the internal connections of this model to the sparse matrix. More...

subroutine	gwt_mc (this, matrix_sln)
	Map the positions of the GWT model connections in the numerical solution coefficient matrix. More...

subroutine	gwt_ar (this)
	GWT Model Allocate and Read. More...

subroutine	gwt_rp (this)
	GWT Model Read and Prepare. More...

subroutine	gwt_dt (this)
	GWT Model time step size. More...

subroutine	gwt_ad (this)
	GWT Model Time Step Advance. More...

subroutine	gwt_cf (this, kiter)
	GWT Model calculate coefficients. More...

subroutine	gwt_fc (this, kiter, matrix_sln, inwtflag)
	GWT Model fill coefficients. More...

subroutine	gwt_cc (this, innertot, kiter, iend, icnvgmod, cpak, ipak, dpak)
	GWT Model Final Convergence Check. More...

subroutine	gwt_cq (this, icnvg, isuppress_output)
	GWT Model calculate flow. More...

subroutine	gwt_bd (this, icnvg, isuppress_output)
	GWT Model Budget. More...

subroutine	gwt_ot_flow (this, icbcfl, ibudfl, icbcun)
	GWT model output routine. More...

subroutine	gwt_ot_dv (this, idvsave, idvprint, ipflag)
	GWT model dependent variable output. More...

subroutine	gwt_da (this)
	Deallocate. More...

subroutine	gwt_bdentry (this, budterm, budtxt, rowlabel)
	GroundWater Transport Model Budget Entry. More...

integer(i4b) function	gwt_get_iasym (this)
	return 1 if any package causes the matrix to be asymmetric. Otherwise return 0. More...

subroutine	allocate_scalars (this, modelname)
	Allocate memory for non-allocatable members. More...

subroutine	package_create (this, filtyp, ipakid, ipaknum, pakname, mempath, inunit, iout)
	Create boundary condition packages for this model. More...

class(gwtmodeltype) function, pointer, public	castasgwtmodel (model)
	Cast to GwtModelType. More...

subroutine	create_bndpkgs (this, bndpkgs, pkgtypes, pkgnames, mempaths, inunits)
	Source package info and begin to process. More...

subroutine	create_gwt_packages (this, indis)
	Source package info and begin to process. More...

Variables
character(len=lenvarname), parameter	dvt = 'CONCENTRATION '
	dependent variable type, varies based on model type More...

character(len=lenvarname), parameter	dvu = 'MASS '
	dependent variable unit of measure, either "mass" or "energy" More...

character(len=lenvarname), parameter	dvua = 'M '
	abbreviation of the dependent variable unit of measure, either "M" or "E" More...

integer(i4b), parameter, public	gwt_nbasepkg = 50
	GWT base package array descriptors. More...

character(len=lenpackagetype), dimension(gwt_nbasepkg), public	gwt_basepkg

integer(i4b), parameter, public	gwt_nmultipkg = 50
	GWT multi package array descriptors. More...

character(len=lenpackagetype), dimension(gwt_nmultipkg), public	gwt_multipkg

integer(i4b), parameter	niunit_gwt = GWT_NBASEPKG + GWT_NMULTIPKG

Function/Subroutine Documentation

◆ allocate_scalars()

subroutine gwtmodule::allocate_scalars	(	class(gwtmodeltype)	this,
		character(len=*), intent(in)	modelname
	)

private

A subroutine for allocating the scalars specific to the GWT model type. Additional scalars used by the parent class are allocated by the parent class.

Definition at line 724 of file gwt.f90.

     ! -- modules
     use memorymanagermodule, only: mem_allocate
     ! -- dummy
     class(GwtModelType) :: this
     character(len=*), intent(in) :: modelname
     !
     ! -- allocate parent class scalars
     call this%allocate_tsp_scalars(modelname)
     !
     ! -- allocate additional members specific to GWT model type
     call mem_allocate(this%inmst, 'INMST', this%memoryPath)
     call mem_allocate(this%indsp, 'INDSP', this%memoryPath)
     !
     this%inmst = 0
     this%indsp = 0

◆ castasgwtmodel()

class(gwtmodeltype) function, pointer, public gwtmodule::castasgwtmodel ( class(*), pointer model )

Parameters

model The object to be cast

Returns: The GWT model

Definition at line 823 of file gwt.f90.

     class(*), pointer :: model !< The object to be cast
     class(GwtModelType), pointer :: gwtmodel !< The GWT model
     !
     gwtmodel => null()
     if (.not. associated(model)) return
     select type (model)
     type is (gwtmodeltype)
       gwtmodel => model
     end select

Here is the caller graph for this function:

◆ create_bndpkgs()

subroutine gwtmodule::create_bndpkgs	(	class(gwtmodeltype)	this,
		integer(i4b), dimension(:), intent(inout), allocatable	bndpkgs,
		type(characterstringtype), dimension(:), intent(inout), pointer, contiguous	pkgtypes,
		type(characterstringtype), dimension(:), intent(inout), pointer, contiguous	pkgnames,
		type(characterstringtype), dimension(:), intent(inout), pointer, contiguous	mempaths,
		integer(i4b), dimension(:), intent(inout), pointer, contiguous	inunits
	)

private

Definition at line 837 of file gwt.f90.

     ! -- modules
     use constantsmodule, only: lenpackagename
     use characterstringmodule, only: characterstringtype
     ! -- dummy
     class(GwtModelType) :: this
     integer(I4B), dimension(:), allocatable, intent(inout) :: bndpkgs
     type(CharacterStringType), dimension(:), contiguous, &
       pointer, intent(inout) :: pkgtypes
     type(CharacterStringType), dimension(:), contiguous, &
       pointer, intent(inout) :: pkgnames
     type(CharacterStringType), dimension(:), contiguous, &
       pointer, intent(inout) :: mempaths
     integer(I4B), dimension(:), contiguous, &
       pointer, intent(inout) :: inunits
     ! -- local
     integer(I4B) :: ipakid, ipaknum
     character(len=LENFTYPE) :: pkgtype, bndptype
     character(len=LENPACKAGENAME) :: pkgname
     character(len=LENMEMPATH) :: mempath
     integer(I4B), pointer :: inunit
     integer(I4B) :: n
     !
     if (allocated(bndpkgs)) then
       !
       ! -- create stress packages
       ipakid = 1
       bndptype = ''
       do n = 1, size(bndpkgs)
         !
         pkgtype = pkgtypes(bndpkgs(n))
         pkgname = pkgnames(bndpkgs(n))
         mempath = mempaths(bndpkgs(n))
         inunit => inunits(bndpkgs(n))
         !
         if (bndptype /= pkgtype) then
           ipaknum = 1
           bndptype = pkgtype
         end if
         !
         call this%package_create(pkgtype, ipakid, ipaknum, pkgname, mempath, &
                                  inunit, this%iout)
         ipakid = ipakid + 1
         ipaknum = ipaknum + 1
       end do
       !
       ! -- cleanup
       deallocate (bndpkgs)
     end if

◆ create_gwt_packages()

subroutine gwtmodule::create_gwt_packages	(	class(gwtmodeltype)	this,
		integer(i4b), intent(in)	indis
	)

Definition at line 891 of file gwt.f90.

     ! -- modules
     use constantsmodule, only: lenpackagename
     use characterstringmodule, only: characterstringtype
     use arrayhandlersmodule, only: expandarray
     use memorymanagermodule, only: mem_setptr
     use memoryhelpermodule, only: create_mem_path
     use simvariablesmodule, only: idm_context
     use gwtmstmodule, only: mst_cr
     use gwtdspmodule, only: dsp_cr
     ! -- dummy
     class(GwtModelType) :: this
     integer(I4B), intent(in) :: indis
     ! -- local
     type(CharacterStringType), dimension(:), contiguous, &
       pointer :: pkgtypes => null()
     type(CharacterStringType), dimension(:), contiguous, &
       pointer :: pkgnames => null()
     type(CharacterStringType), dimension(:), contiguous, &
       pointer :: mempaths => null()
     integer(I4B), dimension(:), contiguous, &
       pointer :: inunits => null()
     character(len=LENMEMPATH) :: model_mempath
     character(len=LENFTYPE) :: pkgtype
     character(len=LENPACKAGENAME) :: pkgname
     character(len=LENMEMPATH) :: mempath
     integer(I4B), pointer :: inunit
     integer(I4B), dimension(:), allocatable :: bndpkgs
     integer(I4B) :: n
     character(len=LENMEMPATH) :: mempathdsp = ''
     !
     ! -- set input memory paths, input/model and input/model/namfile
     model_mempath = create_mem_path(component=this%name, context=idm_context)
     !
     ! -- set pointers to model path package info
     call mem_setptr(pkgtypes, 'PKGTYPES', model_mempath)
     call mem_setptr(pkgnames, 'PKGNAMES', model_mempath)
     call mem_setptr(mempaths, 'MEMPATHS', model_mempath)
     call mem_setptr(inunits, 'INUNITS', model_mempath)
     !
     do n = 1, size(pkgtypes)
       !
       ! attributes for this input package
       pkgtype = pkgtypes(n)
       pkgname = pkgnames(n)
       mempath = mempaths(n)
       inunit => inunits(n)
       !
       ! -- create dis package as it is a prerequisite for other packages
       select case (pkgtype)
       case ('MST6')
         this%inmst = inunit
       case ('DSP6')
         this%indsp = 1
         mempathdsp = mempath
       case ('CNC6', 'SRC6', 'LKT6', 'SFT6', &
             'MWT6', 'UZT6', 'IST6', 'API6')
         call expandarray(bndpkgs)
         bndpkgs(size(bndpkgs)) = n
       case default
         ! TODO
       end select
     end do
     !
     ! -- Create packages that are tied directly to model
     call mst_cr(this%mst, this%name, this%inmst, this%iout, this%fmi)
     call dsp_cr(this%dsp, this%name, mempathdsp, this%indsp, this%iout, &
                 this%fmi)
     !
     ! -- Check to make sure that required ftype's have been specified
     call this%ftype_check(indis, this%inmst)
     !
     call this%create_bndpkgs(bndpkgs, pkgtypes, pkgnames, mempaths, inunits)

Here is the call graph for this function:

◆ gwt_ac()

subroutine gwtmodule::gwt_ac	(	class(gwtmodeltype)	this,
		type(sparsematrix), intent(inout)	sparse
	)

Definition at line 198 of file gwt.f90.

     ! -- modules
     use sparsemodule, only: sparsematrix
     ! -- dummy
     class(GwtModelType) :: this
     type(sparsematrix), intent(inout) :: sparse
     ! -- local
     class(BndType), pointer :: packobj
     integer(I4B) :: ip
     !
     ! -- Add the internal connections of this model to sparse
     call this%dis%dis_ac(this%moffset, sparse)
     if (this%indsp > 0) &
       call this%dsp%dsp_ac(this%moffset, sparse)
     !
     ! -- Add any package connections
     do ip = 1, this%bndlist%Count()
       packobj => getbndfromlist(this%bndlist, ip)
       call packobj%bnd_ac(this%moffset, sparse)
     end do

Here is the call graph for this function:

◆ gwt_ad()

subroutine gwtmodule::gwt_ad ( class(gwtmodeltype) this )

Call the advance subroutines of the attached packages

Definition at line 352 of file gwt.f90.

     ! -- modules
     use simvariablesmodule, only: isimcheck, ifailedstepretry
     ! -- dummy
     class(GwtModelType) :: this
     class(BndType), pointer :: packobj
     ! -- local
     integer(I4B) :: irestore
     integer(I4B) :: ip, n
     !
     ! -- Reset state variable
     irestore = 0
     if (ifailedstepretry > 0) irestore = 1
     if (irestore == 0) then
       !
       ! -- copy x into xold
       do n = 1, this%dis%nodes
         if (this%ibound(n) == 0) then
           this%xold(n) = dzero
         else
           this%xold(n) = this%x(n)
         end if
       end do
     else
       !
       ! -- copy xold into x if this time step is a redo
       do n = 1, this%dis%nodes
         this%x(n) = this%xold(n)
       end do
     end if
     !
     ! -- Advance fmi
     call this%fmi%fmi_ad(this%x)
     !
     ! -- Advance
     if (this%indsp > 0) call this%dsp%dsp_ad()
     if (this%inssm > 0) call this%ssm%ssm_ad()
     do ip = 1, this%bndlist%Count()
       packobj => getbndfromlist(this%bndlist, ip)
       call packobj%bnd_ad()
       if (isimcheck > 0) then
         call packobj%bnd_ck()
       end if
     end do
     !
     ! -- Push simulated values to preceding time/subtime step
     call this%obs%obs_ad()

Here is the call graph for this function:

◆ gwt_ar()

subroutine gwtmodule::gwt_ar ( class(gwtmodeltype) this )

private

This subroutine:

allocates and reads packages that are part of this model,
allocates memory for arrays used by this model object

Definition at line 250 of file gwt.f90.

     ! -- modules
     use constantsmodule, only: dhnoflo
     ! -- dummy
     class(GwtModelType) :: this
     ! -- locals
     integer(I4B) :: ip
     class(BndType), pointer :: packobj
     !
     ! -- Allocate and read modules attached to model
     call this%fmi%fmi_ar(this%ibound)
     if (this%inmvt > 0) call this%mvt%mvt_ar()
     if (this%inic > 0) call this%ic%ic_ar(this%x)
     if (this%inmst > 0) call this%mst%mst_ar(this%dis, this%ibound)
     if (this%inadv > 0) call this%adv%adv_ar(this%dis, this%ibound)
     if (this%indsp > 0) call this%dsp%dsp_ar(this%ibound, this%mst%thetam)
     if (this%inssm > 0) call this%ssm%ssm_ar(this%dis, this%ibound, this%x)
     if (this%inobs > 0) call this%obs%tsp_obs_ar(this%ic, this%x, this%flowja)
     !
     ! -- Set governing equation scale factor. Note that this scale factor
     ! -- cannot be set arbitrarily. For solute transport, it must be set
     ! -- to 1.  Setting it to a different value will NOT automatically
     ! -- scale all the terms of the governing equation correctly by that
     ! -- value. This is because much of the coding in the associated
     ! -- packages implicitly assumes the governing equation for solute
     ! -- transport is scaled by 1. (effectively unscaled).
     this%eqnsclfac = done
     !
     ! -- Call dis_ar to write binary grid file
     !call this%dis%dis_ar(this%npf%icelltype)
     !
     ! -- set up output control
     call this%oc%oc_ar(this%x, this%dis, dhnoflo, this%depvartype)
     call this%budget%set_ibudcsv(this%oc%ibudcsv)
     !
     ! -- Package input files now open, so allocate and read
     do ip = 1, this%bndlist%Count()
       packobj => getbndfromlist(this%bndlist, ip)
       call packobj%set_pointers(this%dis%nodes, this%ibound, this%x, &
                                 this%xold, this%flowja)
       ! -- Read and allocate package
       call packobj%bnd_ar()
     end do

Here is the call graph for this function:

◆ gwt_bd()

subroutine gwtmodule::gwt_bd	(	class(gwtmodeltype)	this,
		integer(i4b), intent(in)	icnvg,
		integer(i4b), intent(in)	isuppress_output
	)

This subroutine: (1) calculates intercell flows (flowja) (2) calculates package contributions to the model budget

Definition at line 543 of file gwt.f90.

     use constantsmodule, only: dzero
     ! -- dummy
     class(GwtModelType) :: this
     integer(I4B), intent(in) :: icnvg
     integer(I4B), intent(in) :: isuppress_output
     ! -- local
     integer(I4B) :: ip
     class(BndType), pointer :: packobj
     !
     ! -- Save the solution convergence flag
     this%icnvg = icnvg
     !
     ! -- Budget routines (start by resetting).  Sole purpose of this section
     !    is to add in and outs to model budget.  All ins and out for a model
     !    should be added here to this%budget.  In a subsequent exchange call,
     !    exchange flows might also be added.
     call this%budget%reset()
     if (this%inmst > 0) call this%mst%mst_bd(isuppress_output, this%budget)
     if (this%inssm > 0) call this%ssm%ssm_bd(isuppress_output, this%budget)
     if (this%infmi > 0) call this%fmi%fmi_bd(isuppress_output, this%budget)
     if (this%inmvt > 0) call this%mvt%mvt_bd(this%x, this%x)
     do ip = 1, this%bndlist%Count()
       packobj => getbndfromlist(this%bndlist, ip)
       call packobj%bnd_bd(this%budget)
     end do

Here is the call graph for this function:

◆ gwt_bdentry()

subroutine gwtmodule::gwt_bdentry	(	class(gwtmodeltype)	this,
		real(dp), dimension(:, :), intent(in)	budterm,
		character(len=lenbudtxt), dimension(:), intent(in)	budtxt,
		character(len=*), intent(in)	rowlabel
	)

This subroutine adds a budget entry to the flow budget. It was added as a method for the gwt model object so that the exchange object could add its contributions.

Definition at line 675 of file gwt.f90.

     ! -- modules
     use constantsmodule, only: lenbudtxt
     use tdismodule, only: delt
     ! -- dummy
     class(GwtModelType) :: this
     real(DP), dimension(:, :), intent(in) :: budterm
     character(len=LENBUDTXT), dimension(:), intent(in) :: budtxt
     character(len=*), intent(in) :: rowlabel
     !
     call this%budget%addentry(budterm, delt, budtxt, rowlabel=rowlabel)

◆ gwt_cc()

subroutine gwtmodule::gwt_cc	(	class(gwtmodeltype)	this,
		integer(i4b), intent(in)	innertot,
		integer(i4b), intent(in)	kiter,
		integer(i4b), intent(in)	iend,
		integer(i4b), intent(in)	icnvgmod,
		character(len=lenpakloc), intent(inout)	cpak,
		integer(i4b), intent(inout)	ipak,
		real(dp), intent(inout)	dpak
	)

private

If MVR/MVT is active, call the MVR convergence check subroutines to force at least 2 outer iterations. The other advanced transport packages are solved in the matrix equations directly which means the solver is completing the necessary checks thereby eliminating need to call package cc routines. That is, no need to loop over active packages and run: call packobjbnd_cc(iend, icnvg, hclose, rclose)

Definition at line 474 of file gwt.f90.

     ! -- dummy
     class(GwtModelType) :: this
     integer(I4B), intent(in) :: innertot
     integer(I4B), intent(in) :: kiter
     integer(I4B), intent(in) :: iend
     integer(I4B), intent(in) :: icnvgmod
     character(len=LENPAKLOC), intent(inout) :: cpak
     integer(I4B), intent(inout) :: ipak
     real(DP), intent(inout) :: dpak
     ! -- local
     ! -- formats
     !
     ! -- If mover is on, then at least 2 outers required
     if (this%inmvt > 0) call this%mvt%mvt_cc(kiter, iend, icnvgmod, cpak, dpak)

◆ gwt_cf()

subroutine gwtmodule::gwt_cf	(	class(gwtmodeltype)	this,
		integer(i4b), intent(in)	kiter
	)

Call the calculate coefficients subroutines of the attached packages

Definition at line 405 of file gwt.f90.

     ! -- modules
     ! -- dummy
     class(GwtModelType) :: this
     integer(I4B), intent(in) :: kiter
     ! -- local
     class(BndType), pointer :: packobj
     integer(I4B) :: ip
     !
     ! -- Call package cf routines
     do ip = 1, this%bndlist%Count()
       packobj => getbndfromlist(this%bndlist, ip)
       call packobj%bnd_cf()
     end do

Here is the call graph for this function:

◆ gwt_cq()

subroutine gwtmodule::gwt_cq	(	class(gwtmodeltype)	this,
		integer(i4b), intent(in)	icnvg,
		integer(i4b), intent(in)	isuppress_output
	)

private

Call the intercell flows (flow ja) subroutine

Definition at line 495 of file gwt.f90.

     ! -- modules
     use sparsemodule, only: csr_diagsum
     ! -- dummy
     class(GwtModelType) :: this
     integer(I4B), intent(in) :: icnvg
     integer(I4B), intent(in) :: isuppress_output
     ! -- local
     integer(I4B) :: i
     integer(I4B) :: ip
     class(BndType), pointer :: packobj
     !
     ! -- Construct the flowja array.  Flowja is calculated each time, even if
     !    output is suppressed.  (flowja is positive into a cell.)  The diagonal
     !    position of the flowja array will contain the flow residual after
     !    these routines are called, so each package is responsible for adding
     !    its flow to this diagonal position.
     do i = 1, this%nja
       this%flowja(i) = dzero
     end do
     if (this%inadv > 0) call this%adv%adv_cq(this%x, this%flowja)
     if (this%indsp > 0) call this%dsp%dsp_cq(this%x, this%flowja)
     if (this%inmst > 0) call this%mst%mst_cq(this%dis%nodes, this%x, this%xold, &
                                              this%flowja)
     if (this%inssm > 0) call this%ssm%ssm_cq(this%flowja)
     if (this%infmi > 0) call this%fmi%fmi_cq(this%x, this%flowja)
     !
     ! -- Go through packages and call cq routines.  cf() routines are called
     !    first to regenerate non-linear terms to be consistent with the final
     !    conc solution.
     do ip = 1, this%bndlist%Count()
       packobj => getbndfromlist(this%bndlist, ip)
       call packobj%bnd_cf()
       call packobj%bnd_cq(this%x, this%flowja)
     end do
     !
     ! -- Finalize calculation of flowja by adding face flows to the diagonal.
     !    This results in the flow residual being stored in the diagonal
     !    position for each cell.
     call csr_diagsum(this%dis%con%ia, this%flowja)

Here is the call graph for this function:

◆ gwt_cr()

subroutine, public gwtmodule::gwt_cr	(	character(len=*), intent(in)	filename,
		integer(i4b), intent(in)	id,
		character(len=*), intent(in)	modelname
	)

Parameters

[in]	filename	input file
[in]	id	consecutive model number listed in mfsim.nam
[in]	modelname	name of the model

Definition at line 100 of file gwt.f90.

     ! -- modules
     use listsmodule, only: basemodellist
     use basemodelmodule, only: addbasemodeltolist
     use constantsmodule, only: lenpackagename
     use memoryhelpermodule, only: create_mem_path
     use memorymanagerextmodule, only: mem_set_value
     use gwtnaminputmodule, only: gwtnamparamfoundtype
     use budgetmodule, only: budget_cr
     ! -- dummy
     character(len=*), intent(in) :: filename !< input file
     integer(I4B), intent(in) :: id !< consecutive model number listed in mfsim.nam
     character(len=*), intent(in) :: modelname !< name of the model
     ! -- local
     integer(I4B) :: indis
     type(GwtModelType), pointer :: this
     class(BaseModelType), pointer :: model
     !
     ! -- Allocate a new GWT Model (this)
     allocate (this)
     !
     ! -- Set memory path before allocation in memory manager can be done
     this%memoryPath = create_mem_path(modelname)
     !
     ! -- Allocate scalars and add model to basemodellist
     call this%allocate_scalars(modelname)
     !
     ! -- set labels for transport model - needed by create_packages() below
     call this%set_tsp_labels(this%macronym, dvt, dvu, dvua)
     !
     model => this
     call addbasemodeltolist(basemodellist, model)
     !
     ! -- Call parent class routine
     call this%tsp_cr(filename, id, modelname, 'GWT', indis)
     !
     ! -- create model packages
     call this%create_packages(indis)

Here is the call graph for this function:

Here is the caller graph for this function:

◆ gwt_da()

subroutine gwtmodule::gwt_da ( class(gwtmodeltype) this )

private

Deallocate memory at conclusion of model run

Definition at line 611 of file gwt.f90.

     ! -- modules
     use memorymanagermodule, only: mem_deallocate
     use memorymanagerextmodule, only: memorystore_remove
     use simvariablesmodule, only: idm_context
     ! -- dummy
     class(GwtModelType) :: this
     ! -- local
     integer(I4B) :: ip
     class(BndType), pointer :: packobj
     !
     ! -- Deallocate idm memory
     call memorystore_remove(this%name, 'NAM', idm_context)
     call memorystore_remove(component=this%name, context=idm_context)
     !
     ! -- Internal flow packages deallocate
     call this%dis%dis_da()
     call this%ic%ic_da()
     call this%fmi%fmi_da()
     call this%adv%adv_da()
     call this%dsp%dsp_da()
     call this%ssm%ssm_da()
     call this%mst%mst_da()
     call this%mvt%mvt_da()
     call this%budget%budget_da()
     call this%oc%oc_da()
     call this%obs%obs_da()
     !
     ! -- Internal package objects
     deallocate (this%dis)
     deallocate (this%ic)
     deallocate (this%dsp)
     deallocate (this%ssm)
     deallocate (this%mst)
     deallocate (this%adv)
     deallocate (this%mvt)
     deallocate (this%budget)
     deallocate (this%oc)
     deallocate (this%obs)
     !
     ! -- Boundary packages
     do ip = 1, this%bndlist%Count()
       packobj => getbndfromlist(this%bndlist, ip)
       call packobj%bnd_da()
       deallocate (packobj)
     end do
     !
     ! -- Scalars
     call mem_deallocate(this%indsp)
     call mem_deallocate(this%inmst)
     !
     ! -- Parent class members
     call this%TransportModelType%tsp_da()
     !
     ! -- NumericalModelType
     call this%NumericalModelType%model_da()

Here is the call graph for this function:

◆ gwt_df()

subroutine gwtmodule::gwt_df ( class(gwtmodeltype) this )

This subroutine defines a gwt model type. Steps include: (1) call df routines for each package (2) set variables and pointers

Definition at line 146 of file gwt.f90.

     ! -- modules
     use simmodule, only: store_error
     ! -- dummy
     class(GwtModelType) :: this
     ! -- local
     integer(I4B) :: ip
     class(BndType), pointer :: packobj
     !
     ! -- Define packages and utility objects
     call this%dis%dis_df()
     call this%fmi%fmi_df(this%dis, 1)
     if (this%inmvt > 0) call this%mvt%mvt_df(this%dis)
     if (this%inadv > 0) call this%adv%adv_df()
     if (this%indsp > 0) call this%dsp%dsp_df(this%dis)
     if (this%inssm > 0) call this%ssm%ssm_df()
     call this%oc%oc_df()
     call this%budget%budget_df(niunit_gwt, this%depvarunit, &
                                this%depvarunitabbrev)
     !
     ! -- Check for SSM package
     if (this%inssm == 0) then
       if (this%fmi%nflowpack > 0) then
         call store_error('Flow model has boundary packages, but there &
           &is no SSM package.  The SSM package must be activated.', &
           terminate=.true.)
       end if
     end if
     !
     ! -- Assign or point model members to dis members
     this%neq = this%dis%nodes
     this%nja = this%dis%nja
     this%ia => this%dis%con%ia
     this%ja => this%dis%con%ja
     !
     ! -- Allocate model arrays, now that neq and nja are assigned
     call this%allocate_arrays()
     !
     ! -- Define packages and assign iout for time series managers
     do ip = 1, this%bndlist%Count()
       packobj => getbndfromlist(this%bndlist, ip)
       call packobj%bnd_df(this%neq, this%dis)
       packobj%TsManager%iout = this%iout
       packobj%TasManager%iout = this%iout
     end do
     !
     ! -- Store information needed for observations
     call this%obs%obs_df(this%iout, this%name, 'GWT', this%dis)

Here is the call graph for this function:

◆ gwt_dt()

subroutine gwtmodule::gwt_dt ( class(gwtmodeltype) this )

Calculate the maximum allowable time step size subject to time-step constraints. If adaptive time steps are used, then the time step used will be no larger than dtmax calculated here.

Definition at line 331 of file gwt.f90.

     use tdismodule, only: kstp, kper
     use adaptivetimestepmodule, only: ats_submit_delt
     ! dummy
     class(GwtModelType) :: this
     ! local
     real(DP) :: dtmax
     character(len=LINELENGTH) :: msg
     dtmax = dnodata
  
     ! advection package courant stability
     call this%adv%adv_dt(dtmax, msg, this%mst%thetam)
     if (msg /= '') then
       call ats_submit_delt(kstp, kper, dtmax, msg)
     end if

Here is the call graph for this function:

◆ gwt_fc()

subroutine gwtmodule::gwt_fc	(	class(gwtmodeltype)	this,
		integer(i4b), intent(in)	kiter,
		class(matrixbasetype), pointer	matrix_sln,
		integer(i4b), intent(in)	inwtflag
	)

private

Call the fill coefficients subroutines attached packages

Definition at line 425 of file gwt.f90.

     ! -- modules
     ! -- dummy
     class(GwtModelType) :: this
     integer(I4B), intent(in) :: kiter
     class(MatrixBaseType), pointer :: matrix_sln
     integer(I4B), intent(in) :: inwtflag
     ! -- local
     class(BndType), pointer :: packobj
     integer(I4B) :: ip
     !
     ! -- call fc routines
     call this%fmi%fmi_fc(this%dis%nodes, this%xold, this%nja, matrix_sln, &
                          this%idxglo, this%rhs)
     if (this%inmvt > 0) then
       call this%mvt%mvt_fc(this%x, this%x)
     end if
     if (this%inmst > 0) then
       call this%mst%mst_fc(this%dis%nodes, this%xold, this%nja, matrix_sln, &
                            this%idxglo, this%x, this%rhs, kiter)
     end if
     if (this%inadv > 0) then
       call this%adv%adv_fc(this%dis%nodes, matrix_sln, this%idxglo, this%x, &
                            this%rhs)
     end if
     if (this%indsp > 0) then
       call this%dsp%dsp_fc(kiter, this%dis%nodes, this%nja, matrix_sln, &
                            this%idxglo, this%rhs, this%x)
     end if
     if (this%inssm > 0) then
       call this%ssm%ssm_fc(matrix_sln, this%idxglo, this%rhs)
     end if
     !
     ! -- packages
     do ip = 1, this%bndlist%Count()
       packobj => getbndfromlist(this%bndlist, ip)
       call packobj%bnd_fc(this%rhs, this%ia, this%idxglo, matrix_sln)
     end do

Here is the call graph for this function:

◆ gwt_get_iasym()

integer(i4b) function gwtmodule::gwt_get_iasym ( class(gwtmodeltype) this )

Definition at line 691 of file gwt.f90.

     class(GwtModelType) :: this
     ! -- local
     integer(I4B) :: iasym
     integer(I4B) :: ip
     class(BndType), pointer :: packobj
     !
     ! -- Start by setting iasym to zero
     iasym = 0
     !
     ! -- ADV
     if (this%inadv > 0) then
       if (this%adv%iasym /= 0) iasym = 1
     end if
     !
     ! -- DSP
     if (this%indsp > 0) then
       if (this%dsp%ixt3d /= 0) iasym = 1
     end if
     !
     ! -- Check for any packages that introduce matrix asymmetry
     do ip = 1, this%bndlist%Count()
       packobj => getbndfromlist(this%bndlist, ip)
       if (packobj%iasym /= 0) iasym = 1
     end do

Here is the call graph for this function:

◆ gwt_mc()

subroutine gwtmodule::gwt_mc	(	class(gwtmodeltype)	this,
		class(matrixbasetype), pointer	matrix_sln
	)

Parameters

matrix_sln global system matrix

Definition at line 223 of file gwt.f90.

     ! -- dummy
     class(GwtModelType) :: this
     class(MatrixBaseType), pointer :: matrix_sln !< global system matrix
     ! -- local
     class(BndType), pointer :: packobj
     integer(I4B) :: ip
     !
     ! -- Find the position of each connection in the global ia, ja structure
     !    and store them in idxglo.
     call this%dis%dis_mc(this%moffset, this%idxglo, matrix_sln)
     !
     if (this%indsp > 0) call this%dsp%dsp_mc(this%moffset, matrix_sln)
     !
     ! -- Map any package connections
     do ip = 1, this%bndlist%Count()
       packobj => getbndfromlist(this%bndlist, ip)
       call packobj%bnd_mc(this%moffset, matrix_sln)
     end do

Here is the call graph for this function:

◆ gwt_ot_dv()

subroutine gwtmodule::gwt_ot_dv	(	class(gwtmodeltype)	this,
		integer(i4b), intent(in)	idvsave,
		integer(i4b), intent(in)	idvprint,
		integer(i4b), intent(inout)	ipflag
	)

private

Definition at line 593 of file gwt.f90.

     class(GwtModelType) :: this
     integer(I4B), intent(in) :: idvsave
     integer(I4B), intent(in) :: idvprint
     integer(I4B), intent(inout) :: ipflag
  
     ! call GWT dependent variable output routines
     if (this%inmst > 0) call this%mst%mst_ot_dv(idvsave)
  
     ! call general transport model dependent variable output routines
     call this%TransportModelType%tsp_ot_dv(idvsave, idvprint, ipflag)
  

◆ gwt_ot_flow()

subroutine gwtmodule::gwt_ot_flow	(	class(gwtmodeltype)	this,
		integer(i4b), intent(in)	icbcfl,
		integer(i4b), intent(in)	ibudfl,
		integer(i4b), intent(in)	icbcun
	)

Save and print flows

Definition at line 575 of file gwt.f90.

     ! dummy
     class(GwtModelType) :: this
     integer(I4B), intent(in) :: icbcfl
     integer(I4B), intent(in) :: ibudfl
     integer(I4B), intent(in) :: icbcun
     ! local
  
     ! call GWT flow output routines
     if (this%inmst > 0) call this%mst%mst_ot_flow(icbcfl, icbcun)
  
     ! call general transport model flow output routines
     call this%TransportModelType%tsp_ot_flow(icbcfl, ibudfl, icbcun)
  

◆ gwt_rp()

subroutine gwtmodule::gwt_rp ( class(gwtmodeltype) this )

Call the read and prepare routines of the attached packages

Definition at line 299 of file gwt.f90.

     ! -- modules
     use tdismodule, only: readnewdata
     ! -- dummy
     class(GwtModelType) :: this
     ! -- local
     class(BndType), pointer :: packobj
     integer(I4B) :: ip
     !
     ! -- In fmi, check for mvt and mvrbudobj consistency
     call this%fmi%fmi_rp(this%inmvt)
     if (this%inmvt > 0) call this%mvt%mvt_rp()
     !
     ! -- Check with TDIS on whether or not it is time to RP
     if (.not. readnewdata) return
     !
     ! -- Read and prepare
     if (this%inoc > 0) call this%oc%oc_rp()
     if (this%inssm > 0) call this%ssm%ssm_rp()
     do ip = 1, this%bndlist%Count()
       packobj => getbndfromlist(this%bndlist, ip)
       call packobj%bnd_rp()
       call packobj%bnd_rp_obs()
     end do

Here is the call graph for this function:

◆ package_create()

subroutine gwtmodule::package_create	(	class(gwtmodeltype)	this,
		character(len=*), intent(in)	filtyp,
		integer(i4b), intent(in)	ipakid,
		integer(i4b), intent(in)	ipaknum,
		character(len=*), intent(in)	pakname,
		character(len=*), intent(in)	mempath,
		integer(i4b), intent(in)	inunit,
		integer(i4b), intent(in)	iout
	)

Call the package create routines for packages activated by the user.

Definition at line 746 of file gwt.f90.

     ! -- modules
     use simmodule, only: store_error
     use gwtcncmodule, only: cnc_create
     use gwtsrcmodule, only: src_create
     use gwtistmodule, only: ist_create
     use gwtlktmodule, only: lkt_create
     use gwtsftmodule, only: sft_create
     use gwtmwtmodule, only: mwt_create
     use gwtuztmodule, only: uzt_create
     use apimodule, only: api_create
     ! -- dummy
     class(GwtModelType) :: this
     character(len=*), intent(in) :: filtyp
     character(len=LINELENGTH) :: errmsg
     integer(I4B), intent(in) :: ipakid
     integer(I4B), intent(in) :: ipaknum
     character(len=*), intent(in) :: pakname
     character(len=*), intent(in) :: mempath
     integer(I4B), intent(in) :: inunit
     integer(I4B), intent(in) :: iout
     ! -- local
     class(BndType), pointer :: packobj
     class(BndType), pointer :: packobj2
     integer(I4B) :: ip
     !
     ! -- This part creates the package object
     select case (filtyp)
     case ('CNC6')
       call cnc_create(packobj, ipakid, ipaknum, inunit, iout, this%name, &
                       pakname, dvt, mempath)
     case ('SRC6')
       call src_create(packobj, ipakid, ipaknum, inunit, iout, this%name, &
                       this%depvartype, pakname)
     case ('LKT6')
       call lkt_create(packobj, ipakid, ipaknum, inunit, iout, this%name, &
                       pakname, this%fmi, this%eqnsclfac, this%depvartype, &
                       this%depvarunit, this%depvarunitabbrev)
     case ('SFT6')
       call sft_create(packobj, ipakid, ipaknum, inunit, iout, this%name, &
                       pakname, this%fmi, this%eqnsclfac, this%depvartype, &
                       this%depvarunit, this%depvarunitabbrev)
     case ('MWT6')
       call mwt_create(packobj, ipakid, ipaknum, inunit, iout, this%name, &
                       pakname, this%fmi, this%eqnsclfac, this%depvartype, &
                       this%depvarunit, this%depvarunitabbrev)
     case ('UZT6')
       call uzt_create(packobj, ipakid, ipaknum, inunit, iout, this%name, &
                       pakname, this%fmi, this%eqnsclfac, this%depvartype, &
                       this%depvarunit, this%depvarunitabbrev)
     case ('IST6')
       call ist_create(packobj, ipakid, ipaknum, inunit, iout, this%name, &
                       pakname, this%fmi, this%mst)
     case ('API6')
       call api_create(packobj, ipakid, ipaknum, inunit, iout, this%name, pakname)
     case default
       write (errmsg, *) 'Invalid package type: ', filtyp
       call store_error(errmsg, terminate=.true.)
     end select
     !
     ! -- Packages is the bndlist that is associated with the parent model
     ! -- The following statement puts a pointer to this package in the ipakid
     ! -- position of packages.
     do ip = 1, this%bndlist%Count()
       packobj2 => getbndfromlist(this%bndlist, ip)
       if (packobj2%packName == pakname) then
         write (errmsg, '(a,a)') 'Cannot create package.  Package name  '// &
           'already exists: ', trim(pakname)
         call store_error(errmsg, terminate=.true.)
       end if
     end do
     call addbndtolist(this%bndlist, packobj)

Here is the call graph for this function:

Variable Documentation

◆ dvt

character(len=lenvarname), parameter gwtmodule::dvt = 'CONCENTRATION '

private

Definition at line 32 of file gwt.f90.

32 character(len=LENVARNAME), parameter :: dvt = 'CONCENTRATION ' !< dependent variable type, varies based on model type

◆ dvu

character(len=lenvarname), parameter gwtmodule::dvu = 'MASS '

private

Definition at line 33 of file gwt.f90.

33 character(len=LENVARNAME), parameter :: dvu = 'MASS ' !< dependent variable unit of measure, either "mass" or "energy"

◆ dvua

character(len=lenvarname), parameter gwtmodule::dvua = 'M '

private

Definition at line 34 of file gwt.f90.

34 character(len=LENVARNAME), parameter :: dvua = 'M ' !< abbreviation of the dependent variable unit of measure, either "M" or "E"

◆ gwt_basepkg

character(len=lenpackagetype), dimension(gwt_nbasepkg), public gwtmodule::gwt_basepkg

Definition at line 75 of file gwt.f90.

75 character(len=LENPACKAGETYPE), dimension(GWT_NBASEPKG) :: GWT_BASEPKG

◆ gwt_multipkg

character(len=lenpackagetype), dimension(gwt_nmultipkg), public gwtmodule::gwt_multipkg

Definition at line 88 of file gwt.f90.

88 character(len=LENPACKAGETYPE), dimension(GWT_NMULTIPKG) :: GWT_MULTIPKG

◆ gwt_nbasepkg

integer(i4b), parameter, public gwtmodule::gwt_nbasepkg = 50

GWT6 model base package types. Only listed packages are candidates for input and these will be loaded in the order specified.

Definition at line 74 of file gwt.f90.

74 integer(I4B), parameter :: GWT_NBASEPKG = 50

◆ gwt_nmultipkg

integer(i4b), parameter, public gwtmodule::gwt_nmultipkg = 50

GWT6 model multi-instance package types. Only listed packages are candidates for input and these will be loaded in the order specified.

Definition at line 87 of file gwt.f90.

87 integer(I4B), parameter :: GWT_NMULTIPKG = 50

◆ niunit_gwt

integer(i4b), parameter gwtmodule::niunit_gwt = GWT_NBASEPKG + GWT_NMULTIPKG

private

Definition at line 94 of file gwt.f90.

94 integer(I4B), parameter :: NIUNIT_GWT = gwt_nbasepkg + gwt_nmultipkg

Data Types

Functions/Subroutines

Variables

Function/Subroutine Documentation

◆ allocate_scalars()

◆ castasgwtmodel()

◆ create_bndpkgs()

◆ create_gwt_packages()

◆ gwt_ac()

◆ gwt_ad()

◆ gwt_ar()

◆ gwt_bd()

◆ gwt_bdentry()

◆ gwt_cc()

◆ gwt_cf()

◆ gwt_cq()

◆ gwt_cr()

◆ gwt_da()

◆ gwt_df()

◆ gwt_dt()

◆ gwt_fc()

◆ gwt_get_iasym()

◆ gwt_mc()

◆ gwt_ot_dv()

◆ gwt_ot_flow()

◆ gwt_rp()

◆ package_create()

Variable Documentation

◆ dvt

◆ dvu

◆ dvua

◆ gwt_basepkg

◆ gwt_multipkg

◆ gwt_nbasepkg

◆ gwt_nmultipkg

◆ niunit_gwt